The Cliffs Of Moher jig

Also known as The Cliffs Of Mohr.

There are 80 recordings of a tune by this name.

The Cliffs Of Moher has been added to 1,249 tunebooks.

Download ABC

Seven settings

X: 1
T: The Cliffs Of Moher
R: jig
M: 6/8
L: 1/8
K: Ador
|:a3 bag| eaf ged| c2A BAG| EFG ABd|
eaa bag| eaf ged|c2A BAG| EFG A3:|
e2e dBA| e2e dBA| GAB dBA| GAB dBd|
e2e dBA| e2e dBA| GAB dBA| EFG A3|
efe dBA| efe dBA|GAB dBA| GAB dBd|
efe ded| cec BeB| GAB dBA| EFG A3|
ABC
X: 2
T: The Cliffs Of Moher
R: jig
M: 6/8
L: 1/8
K: Gmaj
|:d|~a3 bag|eaf ged|c2A BAG|EFG A2e|
~a3 bag|e/f/af ged|cBA BAG|EFG A2:|
|:d|~e3 dBA|~e dBA|G2B dBA|~G3 dBd|
[1~e3 dBA|e/f/ge dBA|GAB dB/c/d|edB A2:|
[2~d3 dee|cee Bee|EFG AGE|dBe A2||
ABC
X: 3
T: The Cliffs Of Moher
R: jig
M: 6/8
L: 1/8
K: Gdor
d|:gfg agf|dge fdc|B2G AGF|DEF G (3ABc|
dgg agf|dge fdc|B2G AGF|DEF G3:|
~d3 cAG|~d3 cAG|FGA cAG|FGA cAc|
~d3 cAG|~d3 cAG|FGA cAG|DEF G3|
~d3 cAG|~d3 cAG|FGA cAG|FGA cAc|
Add edd|cdd =Bdd|G=Bd D^FA|G=Bd f2 d||
ABC
X: 4
T: The Cliffs Of Moher
R: jig
M: 6/8
L: 1/8
K: Gmaj
d|gfg agf|dgg fdc|AGG (A/2G/2FE)|DGG AGG|
gfg agf|dgg fdc|AGG (A/2G/2FE)|DGG G2:|
|:A|ded cAA|ded cAG|(F/2G/2A).B cAG|(F/2G/2A).B c2A|
ded cAA|ded cAG|(F/2G/2A).B cAG|FGG G2:|
ABC
X: 5
T: The Cliffs Of Moher
R: jig
M: 6/8
L: 1/8
K: Ador
|:a3 bag| eaf ged| c2A BAG| EFG ABd|
efe ded| cec BeB| GAB dBA| EFG |
ABC
X: 6
T: The Cliffs Of Moher
R: jig
M: 6/8
L: 1/8
K: Ador
eaa bag|eaf ged|c2A BAG|EFG ABd|
eaa bag|eaf ged|c2A BAG|EFG A3:|
|:efe dBA|efe dBA|GAB dBA|GAB dBd|
|1efe dBA|efe dBA|GAB dBG|EFG A3:|
|2efe dee|cee Bee|EFG BAG|EDB, A,3|]
ABC
X: 7
T: The Cliffs Of Moher
R: jig
M: 6/8
L: 1/8
K: Ador
|:a2 a bag|a2 a ged|c2 c BAG|A2 A GED|
E aa bag|eaf ged|c AA BAG|EFG A2 a||
aea bag|a2 a ged|c AA B GG|A EE GED|
E aa bag|a2 a ged|c2 c BAG|EFG ABd||
e2 e dBA|ABe dBA|G2 d dBA|GAB dBd|
efe dBA|ABd dBA|GAB dBG|EFG ABd||
e2 e edB|ege dBA|G2 d dBA|GA B-B dd|
B ee f ee|d ee c ee |Ace E^GB|Aed efg:|
"^CODA"a2 a bag|a2 a ged|c2 c BAG|EDC HA,3|]
ABC

Twelve comments

This tune sounds just as good played fast as it does played slowly. However, I find that I can put more expression into the music at the slower speed.

Given the title of the tune, it might be safe to assume that this is a County Clare tune. The Clare style of playing tends to be slower than in other regions, with a distinctly sad, or "blue" sound.

Sliding up to notes, especially the opening A, sounds nice. Don’t worry if your intonation isn’t perfect; that’s part of the Clare sound, too. :)

On the last round of playing this tune try finishing on a low A. This means replacing the last bar with EDC A.

I think the ending in the last two bars is nicer as efgbaged(low)ba. its really nice as a variation

“The Cliffs of Moher” by Skip Healy

T:Cliffs of Moher
M:6/8
L:1/8
S:Skip Healy - have ye this one\have ye this one
R:jig
Z:gm
K:G maj
d|:~a3 bag|eaf ged|c2A BAG|EFG A2e|~a3 bag|e/f/af ged|cBA BAG|EFG A2:|:d|~e3 dBA|~e dBA|G2B dBA|~G3 dBd|1~e3 dBA|e/f/ge dBA|GAB dB/c/d|edB A2:|2~d3 dee|cee Bee|EFG AGE|dBe A2||

Cliff of Moher - Paddy Canny’s setting

As taught to a friend by Patrick Ourceau. I just love the turn on the end of the B part. To wrap this setting up, it seems best to end on the A part.

X: 1
T: Cliffs Of Moher, The
M: 6/8
L: 1/8
R: jig
K: Gdor
d|:gfg agf|dge fdc|B2G AGF|DEF G (3ABc|
dgg agf|dge fdc|B2G AGF|DEF G3:|
~d3 cAG|~d3 cAG|FGA cAG|FGA cAc|
~d3 cAG|~d3 cAG|FGA cAG|DEF G3|
~d3 cAG|~d3 cAG|FGA cAG|FGA cAc|
Add edd|cdd =Bdd|G=Bd D^FA|G=Bd f2 d||

Ken

…and in O’Neill’s you would find this…

X: 861
T: The Cliffs Of Moher
S: O’Neill’s Music Of Ireland
R: jig
M: 6/8
L: 1/8
K: G
d|gfg agf|dgg fdc|AGG (A/2G/2FE)|DGG AGG|
gfg agf|dgg fdc|AGG (A/2G/2FE)|DGG G2:|
|:A|ded cAA|ded cAG|(F/2G/2A).B cAG|(F/2G/2A).B c2A|
ded cAA|ded cAG|(F/2G/2A).B cAG|FGG G2:|

Chopping Cliffs of Moher

Kevin Burke chops off the very last dotted crotchet (the A3) just before going back to playing the tune a second time through.

|:a3 bag| eaf ged| c2A BAG| EFG ABd|

etc to last line

efe ded| cec BeB| GAB dBA| EFG | and back to start.

It works really well.

The Cliffs of Moher

P.J. Hernon recorded a G major version of the tune, which is close to what "WhistlinLeeds" posted above.

There’s a very similar G major jig called "An Tiochfaidh Tu Abhaile Liom": http://www.thesession.org/tunes/1220

Cliffs of Moher - Johnny McCarthy’s setting

Setting 7 here is my transcription of Clare accordion player Johnny McCarthy’s recording from his CD "Steele’s Rock". He plays it twice through with very little variation and then ends with half of the A part. I’ve omitted the cuts he uses (mostly on the long notes at the start of measures). Other than that, I’m not hearing ornamentation. This is the second tune of a set starting with Banish Misfortune. I added his setting of that yesterday.