Dinkey’s reel

Also known as Dinkey Dorian’s, Dinkey Dorrian’s, Dinkie Dorian’s, Dinkie Dorrian’s, Dinkie’s, Dinkies, Dinky’s.

There are 43 recordings of a tune by this name.

Dinkey's has been added to 560 tunebooks.

Download ABC

Five settings

X: 1
T: Dinkey's
R: reel
M: 4/4
L: 1/8
K: Amix
|:ed|c2B2 ABcd|egfg edBd|gBBB gBaB|gBBB gfed|
cdBc ABcd|egfg edBd|gfgd efed|c2B2 A2:|
|:eg|aAAA aAbA|aAAA agef|gBBB gBaB|gBBB gfeg|
aAAA aAbA|aAAA agef|gfgd efed|cdBc A2:|
ABC
X: 2
T: Dinkey's
R: reel
M: 4/4
L: 1/8
K: Dmaj
| {g}ed |: {g}cd{g}B{d}c {g}AB{g}cd | {g}eg{a}fd {g}e2 {A}ef | {a}gB{gBdBGB}B2 {a}gBaB| {a}gB{gBdBGB}B2 gf{g}ed |
| {g}cd{g}B{d}c {g}AB{g}cd | {g}eg{a}fd {g}e2 {A}ef | g{a}g{f}gd {g}ef{g}ed| {g}cd{g}B{d}c [1 {g}A2 {g}ed :| [2 {g}A2 (3 {g}efg |
|: aA {gAGAG}A2 aAgA |aA{gAGAG}A2 ag{a}ef | {a}gB{gBdBGB}B2 {a}gBaB| {a}gB{gBdBGB}B2 ag{a}eg |
| [1 aA {gAGAG}A2 aAgA |aA{gAGAG}A2 ag{a}ef | g{a}g{f}gd {g}ef{g}ed| {g}cd{g}B{d}c {g}A2 (3{g}efg :|
| [2 aA{gAGAG}A2 {a}gA{gAGAG}A2 | {g}fA {gAGAG}A2 {g}e4 | g{a}g{f}gd {g}ef{g}ed| {g}cd{g}B{d}c {g}A4 |
ABC
X: 3
T: Dinkey's
R: reel
M: 4/4
L: 1/8
K: Amix
|:eg | aAAA aAbA | aAAA agef | gBBB gBaB | gBBB gfeg |
aAAA gAAA | fAAA e2ef | gfgd efed | cdBc A2:|
ABC
X: 4
T: Dinkey's
R: reel
M: 4/4
L: 1/8
K: Amix
| (3cdc (3BcB ABcd | e^gfd edcd | gB (3BBB gBaB | gB (3BBB gaed |
(3cdc (3BcB ABcd | e^gfd edcd | gfge dfed |1 (3cdc (3BcB A>fed :|2 (3cdc (3BcB A>f^gd |
|: aA (3AAA aAbA | aA (3AAA {ab}aefg | gB (3BBB gBaB | gB (3BBB gef^g |
|1 aA (3AAA aAbA | aA (3AAA {ab}agef | gfge dfed | (3cdc (3BcB A>ef^g :|
|2 aA (3AAA gA (3AAA | fA (3AAA edef | gfge dfed | (3cdc (3BcB A>fed ||
ABC
X: 5
T: Dinkey's
R: reel
M: 4/4
L: 1/8
K: Amix
|: fed | "A"{cd}c2 Bc ABcd | "Em"egfd edBd | "G"gB B/B/B gBaB | gB B/B/B gfed |
"A"{cd}c2 Bc ABcd | "Em"egfd edBd | "G"{a}(gfg)e "D"dfed | "E7"cdBc "A"A :|
|: ef^g | "A"aA A/A/A aAbA | aA A/A/A {b}agef | "G"gB B/B/B gBaB | gB B/B/B "Em"{a}gfeg |
[1 "A"aA A/A/A aAbA | aA A/A/A {b}agef | "G"{a}(gfg)e "D"dfed | "E7"cdBc "A"A :|
[2 "A"aA A/A/A "G"gA A/A/A | "D"fA A/A/A "A"eA A/A/A | "G"{a}(gfg)e "D"dfed | "E7"cdBc "A"A |]
# Added by Tate .
ABC

Sixteen comments

The C and B at the very start of the tune can be turned into triplets, CDC BCB, but make sure the melody doesn’t get buried underneath too many triplets.

If you’re playing this on the fiddle, mandolin or any other instrument tuned GDAE, try playing the open E string at the same time as the C and B at the start and end of the first part.

Dinkey’s was composed by the late Francie Dearg O Beirn of Kilcar, a modest man and outstanding fiddler, who apparently did not take credit for his tunes.

I’ve a tape of the piper Jerry O’Sullivan playing this in D, where it goes great on the pipes.

Posted by .

Composed by Dinky Dorrian himself?

The sleeve notes from Altan’s CD ‘Horse with a Heart’ (1989) say "Francie Byrne leanred the reel commonly known as Dinky’s from Dinky Dorrian, a travelling musician". It’s another one of those composed by or played by or named after situations. Whoever composed it, it’s a first rate tune - and Dorrian is a great name for a musician too!

A scottish smallpipe version

X:1
T:Dinky Dorian’s
M:2/4
K:D
| {g}ed |: {g}cd{g}B{d}c {g}AB{g}cd | {g}eg{a}fd {g}e2 {A}ef | {a}gB{gBdBGB}B2 {a}gBaB| {a}gB{gBdBGB}B2 gf{g}ed |
%
| {g}cd{g}B{d}c {g}AB{g}cd | {g}eg{a}fd {g}e2 {A}ef | g{a}g{f}gd {g}ef{g}ed| {g}cd{g}B{d}c [1 {g}A2 {g}ed :| [2 {g}A2 (3 {g}efg |
%
|: aA {gAGAG}A2 aAgA |aA{gAGAG}A2 ag{a}ef | {a}gB{gBdBGB}B2 {a}gBaB| {a}gB{gBdBGB}B2 ag{a}eg |
%
| [1 aA {gAGAG}A2 aAgA |aA{gAGAG}A2 ag{a}ef | g{a}g{f}gd {g}ef{g}ed| {g}cd{g}B{d}c {g}A2 (3{g}efg :|
%
| [2 aA{gAGAG}A2 {a}gA{gAGAG}A2 | {g}fA {gAGAG}A2 {g}e4 | g{a}g{f}gd {g}ef{g}ed| {g}cd{g}B{d}c {g}A4 |

Video

They’re red hot on the bowed triplets, aren’t they? I’m gonna practice until I can play them like that….. just as soon as I stop browsing internet forums!

Francie O’Byrne video

I think they’re playing G#s instead of naturals - sounds awesome!

Great Vermont tenor banjo player

does anyone know a tenor banjo player from VT who plays Dinky’s Reel? He and his wife,a fiddler, came to Cape Cod about 8 years ago and played it. I had to learn it after that… I just want to thank him for sharing such a great tune, he’s in the Killington area.

Little known fact:

The Dorian mode is named after Dinkie Dorian. It’s true, because it’s on teh internets.

Theres a second ending to the b part, and this sure takes the roof off! I’ll try post it soon as. Heard it many a time in Donegal, always a crowd pleaser, often followed by Boys of Malin.

I learned a second ending to the b-part, maybe this is what you are talking about..
This is the B-part:

|:eg | aAAA aAbA | aAAA agef | gBBB gBaB | gBBB gfeg |
aAAA gAAA | fAAA e2ef | gfgd efed | cdBc A2:|

Francis Dearg Byrne and Peter Carr setting

I’ve added a transcription of Francis Byrne and his nephew Peter playing from the "Come West Along The Road" segment as posted by ceolachan.