Willafjord reel

Also known as Villafjord, Willa Fjord, Willafiord, Willow Fjord, Wullafjord.

There are 13 recordings of a tune by this name.

Willafjord has been added to 225 tunebooks.

Download ABC

Six settings

X: 1
T: Willafjord
R: reel
M: 4/4
L: 1/8
K: Dmaj
B2| A2F A2D FA | B2G B2D GB | A2F A2D FA |EFGA GFED |
A2F A2D FA | B2G B2D GB |ABcd efge | f2d2 d2 :|
de | f2d f2f df | geaf gfed |f2d f2A df | e2ce Aece|
f2d f2f df | gdaf gfed | ABcd efge | f2d2 d2 :|
ABC
X: 2
T: Willafjord
R: reel
M: 4/4
L: 1/8
K: Dmaj
B2|A2FA- ADFA|B2GB- BDGB|A2FA- ADFA|EFGA GFED|
A2FA- ADFA|B2GB- BDGB|ABcd efge|f2d2 d2:|
|:e2|f2df- ffdf|geaf gfeg|f2df- fAdf|e2ce- eAce|
f2df- ffdf|geaf gfed|ABcd efge|f2d2 d2:|
ABC
X: 3
T: Willafjord
R: reel
M: 4/4
L: 1/8
K: Dmaj
| e2 ce Aece | & | e2 ce- eAce |
| gdaf gfed | & | geaf gfed |
ABC
X: 4
T: Willafjord
R: reel
M: 4/4
L: 1/8
K: Dmaj
A2 FA DAFA | B2 GB DBGB | A2 FA D2 FA | EFGA G2 (3FED |
ADFA DAFA | BDGB D2 BG | A2 (3Bcd ef (3gfe | fd (3edc d2 :|
f2 df Afdf | geaf gfeg | fAdf Afdf | (3eee ce Aece |
(3fff df Af (3fff | geaf gfec | ABcd e2 (3gfe | f2 e2 d2- :|
ABC
X: 5
T: Willafjord
R: reel
M: 4/4
L: 1/8
K: Dmaj
(dB)|vA2u(FA) vDuAvFuA|B2(GB) DBGB|A2(FA) DAFA|EFGA GFED|
A2(FA) DAFA|B2(GB) DBGB|ABcd efge|f2d2 d2:|
(de)|f2(df) Afdf|geaf gfeg|f2(df) Afdf|e2(ce) Aece|
f2(df) Afdf|geaf gfec|ABcd efge|f2d2 d2:|
ABC
X: 6
T: Willafjord
R: reel
M: 4/4
L: 1/8
K: Dmaj
V:1
|"D"A2FA- ADFA|"G"B2GB- BDGB|"D"A2FA- ADFA|"Em"EFGA "A7"GFED|
V:2
|f2 df fAdf|g2 dg gBdg|f2 df fAdf|gfef edcA|
V:3
|d2 Ad dFAd|d2 Bd dGBd|d2 Ad dFAd|edcd cB A2|
V:1
"D"A2 FA ADFA|"G"B2 GB- BDGB|"D/A"ABcd "A7"efge|"D"f2 "G"d2 "D"d2:||
V:2
f2 df- fAdf|g2 dg gBde|fgaf gABc|d2 G2 F2:||
V:3
d2 Ad dFAd|d2 Bd dGBd|A4 Bcde|d2 B2 A2:||
V:1
"D"f2 df- fAdf|"G"ge"D"af "Em"gf"A7"ed|"D"f2 df fAdf|"Em"edcB "A7"ABce|
V:2
A2 FA ADFA|BGFA BAGF|A2 FA ADFA|GFEG AGEG|
V:3
d2 Ad dFAd|d2 d2 d2 A2|d2 Ad dFAd|BAGB cdeA|
V:1
"D"f2 df fAdf|"G"ge"D"af "Em"gfed|"A7"ABcd efge|"D"f2 "G"d2 "D"d2:||
V:2
A2 FA ADFA|BGFA BAGF|A2 GF GABc|d2 G2 F2:||
V:3
d2 Ad dFAd|d2 d2 d2 B2|cdeA Bcde|d2 B2 A2:||
# Added by JACKB .
ABC

Twenty-four comments

Title misspelled

The first time I came across this tune was in 80s. It was published in a tunebook called "Haand me doon da fiddle" under the title of "Willafjord". The book was written by Shetland Fiddler Tom Anderson with one of his fiddle students, Pam Swing, an American from Chicago, and published by the Department of Continuing Education, the University of Stirling, Scotland. Don

Willafjord

Here is the version I used to play at school:

X: 1
T: Willafjord
M: 4/4
L: 1/8
R: reel
K: Dmaj
B2|A2FA- ADFA|B2GB- BDGB|A2FA- ADFA|EFGA GFED|
A2FA- ADFA|B2GB- BDGB|ABcd efge|f2d2 d2:|
|:e2|f2df- ffdf|geaf gfeg|f2df- fAdf|e2ce- eAce|
f2df- ffdf|geaf gfed|ABcd efge|f2d2 d2:|

I’ll have to listen more closely to my Lindsay Porteous recording of this… I like both the transcripts here, but your’s is more familiar with me, but maybe it’s just that similarity to "The Kilfenora"… I think I might have it on another recording. If I do and it’s here and I find it I’ll add it to ‘Recordings’…

Thanks Mark…

You played it at school? Was that last year?

Can you still remember "school"?

“Wllafjord”

Aside from your notation, which was more familiar to me, for example | A2 FA- ADFA | rather than | A2 F A2 D FA | ~ the B-part is the only real difference, and then only in the 4th measures:

| e2 ce Aece | & | e2 ce- eAce |

and the 6th measures:

| gdaf gfed | & | geaf gfed |

I originally learned this one from Pam Swing… I’ll have to see if I’ve any notes for it or can call it up from deep down in the memory banks, though the latter will undoubtedly be ‘polluted’… ;-)

"School" like "Student" is a state of mind… I much prefer the latter… :-P

Damn Dow, my chair just slipped and I gave myself an espresso shower… Have you got one of those dolls there you’re sticking pins into?

“Willafjord” ~ Pam Swing’s transcription

Hey, this is pretty amazing, Pam Swing’s notation is note for note the same as yours Mark, with just one exception, in the B-part, that 6th measure again and just one note:

| geaf gfec |

Strange but true……………..

3 years ago I had a student from Co. Clare at a music school here in Aberdeen. She was here to study whistle, but her main instrument was the concertina. I took her and her friends down to the Tuesday night session, and she started playing “The Kilfenora” reel. [ see link above ]. About 3 bars into it, everyone else started playing “Willafjord”.
The following year I was in a session at the Willie Clancy week. Two well-known box players, 2 well-known fiddle players, RonP , myself and a few others. One of the fiddlers knew a fair number of Shetland tunes, and started “Willafjord”. The other fiddler, and one of the box-players went into “The Kilfenora Reel”.
So, “ceolachan” – do you know Lindsay Porteous ?

Posted by .

“Willafjord” / “Willa Fjord” ~ sans syncopation

dB |
A2 FA DAFA | B2 GB DBGB | A2 FA D2 FA | EFGA G2 (3FED |
ADFA DAFA | BDGB D2 BG | A2 (3Bcd ef (3gfe | fd (3edc d2 :|
|: de |
f2 df Afdf | geaf gfeg | fAdf Afdf | (3eee ce Aece |
(3fff df Af (3fff | geaf gfec | ABcd e2 (3gfe | f2 e2 d2- :|

No Kenny, I never had the pleasure, but I have a recording of him I very much enjoy… I like your tale. It has happened to me a few times all on my lonesome… ;-)

“Willafjord” ~ Nigel Gatherer’s site ~ with tab and chords and notes:

http://www.nigelgatherer.com/
http://www.nigelgatherer.com/tunes/tab/tab4/willa.html

"The great Shetland collector Tom Anderson said that Willafjord was brought back from the Greenland whaling expeditions by Shetland fiddlers and as long since become a standard of the genre. ~ ~ ~ He also said that Willafjord is played in Newfoundland and Cape Breton using the same bowing strokes as in Shetland."

& from that site here’s a loose translation of Tom Anderson’s words given above in dialect:

"In other words, think of walking along with one foot in the ditch, bopping along, and you’ll get the rhythm!"

Here it has a second violin part. It is my understanding that this is something that wasn’t unknown in the Shetlands. Pam Swing and Tom Anderson used to play parts on many of his compositions and with other Shetland standards. I know in Eire that playing in octaves was not unknown:

http://www.sibeliusmusic.com/cgi-bin/show_score.pl?scoreid=34859

Note: The link to the Sibelius score, which you can print out and hear the midi for, does not in any way constitute a recommendation of the second part… ;-)

Willafjord/Villafjord

I heard this one at Majors Creek festival - in the session bar people referred to it as Villafjord. It was quite a while before Davydd from Brisbane pointed me to this tune :-)

Cheers
Jerry

Shetland fiddler Brian Gear plays this without syncopation, thus:
X: 1
T: Willafjord
M: C|
L: 1/8
K: D
(dB)|vA2u(FA) vDuAvFuA|B2(GB) DBGB|A2(FA) DAFA|EFGA GFED|
A2(FA) DAFA|B2(GB) DBGB|ABcd efge|f2d2 d2:|
(de)|f2(df) Afdf|geaf gfeg|f2(df) Afdf|e2(ce) Aece|
f2(df) Afdf|geaf gfec|ABcd efge|f2d2 d2:|

In the late 70’s or early 80’s a Faroese band called (something like) Spaelmenninir i Hoydolum toured New England, and played several afternoon concerts paired with evening contra-dances, using local callers. At one of these evening contras (my memory says it was at the YWCA in Central Sq., Cambridge), they pulled out this tune, whose name I have misremembered all these years as "Wullafjord". The dancers went nuts, as the tune was completely unfamiliar to most of us, but it was so perfectly contra-ish.

Somewhere around the same time, somebody I trusted (perhaps it was Pam Swing) assured me that the unsyncopated tune was the older version, and that the syncopation was a recent innovation.

Posted by .

One step away from the Bayou

the syncopation in this version submitted by Redbird, as opposed to the ‘school’ version of Dr.Dow, for instance, makes it comparable to The Happy One Step http://www.thesession.org/tunes/952 popularised by (both a TV ad and) Sharon Shannon..

of course the respective melodies of these tunes are different, Willafjord being heptatonic to begin with.

Goes well after St.Anne’s Reel

Willafjord and St.Anne’s go together quite well, especially if you play St.Anne’s first with a bit of the Willafjord swing on it.