Eileen O’Brien’s reel

Also known as Conor Tully’s No.1.

There are 10 recordings of a tune by this name.

Eileen O'Brien's has been added to 37 tunebooks.

Download ABC

Five settings

X: 1
T: Eileen O'Brien's
R: reel
M: 4/4
L: 1/8
K: Cmaj
c2Gc AGED|CDEG cGBd|cGGc AGEG|cAGE EDCA,|
G,A,CD ~E3G|AG^FA GABG|~c3B cAGc|cAGE DdcB:|
|:c2ec GAcd|egde cBGA|_B2dB FBdB|c_Bdc BGFG|
~c3d ec~c2|ecdB cBG^f|gedB cAGE|1 FAGF ECEG:|2 ~F3E FGAB||
ABC
X: 2
T: Eileen O'Brien's
R: reel
M: 4/4
L: 1/8
K: Cmaj
c2Gc AGED|CDEG cGBd|cG~G2 AGEG|cAGE DCA,C|
G,A,CD EG~G2|AG^FA GABG|cBcd cAGA|cAGE DdcB:|
|:c2ec GAcd|egde cBGA|_B2dB fBdB|c_BGA BG~G2|
cdec GAcd|egde cBG^f|g=fdc Bcdc|BGFD CDEG:|
c2Bc AE~E2|CDEG cede|cG~G2 AGEG|GAGE EDCA,|
G,A,CD ~E3G|AGFA GcAB|(3cde dB cAdc|AGED CDEG|
~c3d AGED|~C3A, G,CEG|BcBc AE~E2|cAGE ~D2CA,|
G,A,CD ~E3G|AGFA GcAB|(3cde dB cAdc|AGED CDEG||
ceAc GAcd|egdB cBGA|_B2dB FBdB|c_BcB BGFG|
~c3d ec~c2|ecdB cBGB|gedB cAGE|FDGE CDEG|
ceAc GAcd|egdB cBGA|~_B3d ~f3a|gfdc _BGFG|
~c3d ec~c2|ecdB cBGB|gedB cAGE|~F3D (3EFG AB||
ABC
X: 3
T: Eileen O'Brien's
R: reel
M: 4/4
L: 1/8
K: Cmaj
dA A2 BAFE | D2 FA defe | dA A2 BAFA | BFAF E2 FE |
D2 FD FA A2 | BAFB ABde | d2 fd Adfg | afeg fd d2 :|
d2 fd Adfg | afge dcAB | =c2 Gc EcGc | d=cAB cAGc |
Addc defg | afge defg | afge dfed | =cAGE ED D2 :|
# Added by Kenny .
ABC
X: 4
T: Eileen O'Brien's
R: reel
M: 4/4
L: 1/8
K: Cmaj
|: cG ~G2 AGEA | GCEG cedB | cG~G2 AcGc | AEGE DCA,C |
G,C~C2 EG~G2 | AG (3FGA G2AB | c2ed cAGc |AEGE D3B:|
|: c2ec gcec |ecde cGGA | _B2dB fBdB |cBGA _B2AB
Gc~c2 ecgf |ecde cdef |gfdB cAGc |AEGE D3B :|
ABC
X: 5
T: Eileen O'Brien's
R: reel
M: 4/4
L: 1/8
K: Cmaj
cG^FG AGEA | GCEG c2ed | c2Gc AcGc | AEGE DCA,C |
G,CB,C EGGB | AG^FA GABd | c3d cAGc | AEGE D2AB :|
c2ec gcec | egdB cAGA | _B2dB fBdB | cAGA _BdAB |
Ac ~c2 ecgf | egdB cdef | gefd ecGc | AEGE D2 AB :|
ABC

Nine comments

Eileen O’Brien’s

This setting is taken from a session recording here in Sydney. I’ve also transcribed 2 more settings - one from Brendan Bulger:

X: 1
T: Eileen O’Brien’s
M: 4/4
L: 1/8
R: reel
K: Cmaj
c2Gc AGED|CDEG cGBd|cG~G2 AGEG|cAGE DCA,C|
G,A,CD EG~G2|AG^FA GABG|cBcd cAGA|cAGE DdcB:|
|:c2ec GAcd|egde cBGA|_B2dB fBdB|c_BGA BG~G2|
cdec GAcd|egde cBG^f|g=fdc Bcdc|BGFD CDEG:|

…and one from John Carty (1st time thru):

X: 1
T: Eileen O’Brien’s
M: 4/4
L: 1/8
R: reel
K: Cmaj
c2Bc AE~E2|CDEG cede|cG~G2 AGEG|GAGE EDCA,|
G,A,CD ~E3G|AGFA GcAB|(3cde dB cAdc|AGED CDEG|
~c3d AGED|~C3A, G,CEG|BcBc AE~E2|cAGE ~D2CA,|
G,A,CD ~E3G|AGFA GcAB|(3cde dB cAdc|AGED CDEG||
ceAc GAcd|egdB cBGA|_B2dB FBdB|c_BcB BGFG|
~c3d ec~c2|ecdB cBGB|gedB cAGE|FDGE CDEG|
ceAc GAcd|egdB cBGA|~_B3d ~f3a|gfdc _BGFG|
~c3d ec~c2|ecdB cBGB|gedB cAGE|~F3D (3EFG AB||

I haven’t got a recording of Eileen herself playing it. Does one exist? If so, could someone transcribe her setting here in the comments please?

Paddy O’Brien’s daughter, isn’t she? Marcas O’Murchu also recorded this tune on the flute.

Yes.

Is there a recording of her playing this tune? I haven’t got Newtown Bridge so am not familiar with it.

Hey, Mark. You can listen to the live recording of her concert with Deidre McSherry on the Net. It’s in the archive of RTE Radio’s The Late Session: http://www.rte.ie/radio1/story/1015109.html (Weds 18th August 2004) She doesn’t play this tune though.

Flute-friendly version

From Marcas O’Murchu :

dA A2 BAFE | D2 FA defe | dA A2 BAFA | BFAF E2 FE |
D2 FD FA A2 | BAFB ABde | d2 fd Adfg | afeg fd d2 :|
d2 fd Adfg | afge dcAB | =c2 Gc EcGc | d=cAB cAGc |
Addc defg | afge defg | afge dfed | =cAGE ED D2 :|

Posted by .

From the CD Echoes Of Erin: Comhaltas Concert Tour 2006
I think the Box player is Padraig King.

cG ~G2 AGEA GCEG cedB cG~G2 AcGc AEGE DCA,C
G,C~C,2 EG~G2 | AG (3FGA G2AB | c2ed cAGc |AEGE D3B
c2ec gcec |ecde cGGA | _B2dB fBdB |cBGA _B2AB
Gc~c2 ecgf |ecde cdef |gfdB cAGc |AEGE D3B |

Version 5 above

is a setting from the lovely playing of Aisling Hunt, a young box player from near Tulla, Co. Clare. It differs from other settings here and from Eileen’s actual rendering.

Setting number 4, from ‘Theirlandais’, is the closest to the notes Eileen O’Brien’s plays. She did indeed compose this tune in the late 1970s and gave it the highly original title ‘Eileen O’Brien’s Reel’. 8)) It’s a fine tune.

I won’t publish the ‘corrrect’ setting here just now as I haven’t asked for her permission to do so - but it would set the record straight.

Regards
David

Posted by .