The Burning Of The Piper’s Hut reel

Also known as The Burning Of The Piper’s Hat, Burning The Piper’s Hut, The Defaulter’s March.

There are 4 recordings of a tune by this name.

The Burning Of The Piper's Hut has been added to 136 tunebooks.

Download ABC

Seven settings

X: 1
T: The Burning Of The Piper's Hut
R: reel
M: 4/4
L: 1/8
K: Emin
|:EFGA B4|BABd B2 AG|F2 D2 A2 D2|FGAB A2 GF|
EFGA B3 B|BABd B2 AG|F2 D2 B2 AG|F2 E2 E3 D:|
|:EFGA B~E3|d~E3 B2 AG|F2 D2 A2 D2|FGAB A2 GF|
EFGA B~E3|d~E3 B2 AG|F2 D2 B2 AG|F2 E2 E3 D:|
# Added .
ABC
X: 2
T: The Burning Of The Piper's Hut
R: reel
M: 4/4
L: 1/8
K: Emin
Bcde f4 | f2 a2 f2 ed | c2 A2 e2 A2 | c2 ef eAcA |
Bcde f4 | f2 a2 f2 ed | c2 A2 f2 c2 |c2 B2 B4 :|
Bcde f2 B2 | a2 B2 f2 ed | c2 A2 e2 A2 | c2 ef eAcA |
Bcde f2 B2 | a2 B2 f2 ed | c2 A2 f2 c2 | c2 B2 B4 :|
Bcde fBce | aBce f2 ed | c2 A2 e2 A2 | c2 ef eAcA |
Bcde fBce | aBce f2 ed | c2 A2 f2 c2 | c2 B2 B4 :|
Bcde fBBB | aBBB fBBB | cAAA eAAA | c2 ef eAcA |
Bcde fBBB | aBBB f2 ed | c2 A2 f2 c2 | c2 B2 B4 :|
# Added by Kenny .
ABC
X: 3
T: The Burning Of The Piper's Hut
R: reel
M: 4/4
L: 1/8
K: Amix
[M:2/4]
B/c/d/e/ f2|f>a fe/d/|c>A d/eA/|c/d/e/f/ e/A/c/A/|
B/c/d/e/ f2|f>a fe/d/|c>A d/fc/|cB B:|
B/c/d/e/ f>B|a>B fe/d/|c>A d/eA/|c/d/e/f/ e/A/c/A/|
B/c/d/e/ fB|aB fe/d/|c>A d/fc/|cB B:|
B/c/d/e/ f/B/B/B/|a/B/B/B/ fe/a/|B/c/d/e/ f/B/B/B/|c/A/A/A/ e/A/A/A/|
B/c/d/e/ f/B/B/B/|a/B/B/B/ fe/d/|c>A d/fc/|cB B:|
B/c/d/e/ f/B/B/B/|a/B/B/B/ f/B/B/B/|B/c/d/e/ f/B/B/B/|c/A/A/A/ e/A/A/A/|
B/c/d/e/ f/B/B/B/|a/B/B/B/ fe/d/|c>A d/fc/|cB B:|
ABC
X: 4
T: The Burning Of The Piper's Hut
R: reel
M: 4/4
L: 1/8
K: Emin
|: D |E>FGA B2 B^A | B>^ABd B2 AG | F2 D2 A2 D2 | FGAB AB/A/ GF |
E>FGA B2 B^A | B>^ABd B2 AG | F2 D2 Bc/B/ AG | F2 E^D E3 :|
|: B |EFGA BEE/E/E | dEE/E/E Bc/B/ AG | F2 D2 A2 D2 | FGAB A2 GF |
EFGA BEE/E/E | dEE/E/E B2 AG | F2 D2 B2 AG | FG/F E^D E3 :|
ABC
X: 5
T: The Burning Of The Piper's Hut
R: reel
M: 4/4
L: 1/8
K: Emin
M:6/8
|: B |E>EE E>FA | B>AB E>FG | F>ED A>FD | F>EF D>EF |
G>FG A>GA | B>cB B>AG | F<DF A>BF | E3 E2 :|
|: B |E>FG G>AB | dBG G>FG | A>FD D>EF | FAF D>EF |
G>FG ABc | dBG G>FG | A>FD D<dF | E3 E2 :|
M: 4/4
|: B |E2 EE E2 FA | B2 AB E2 FG | F2 ED A2 FD | F2 EF D2 EF |
G2 FG A2 GA | B2 cB B2 AG | FD- DF A2 BF | E4 E3 :|
|: B |E2 FG G2 AB | dB G2 G2 FG | A2 FD D2 EF | FA F2 D2 EF |
G2 FG ABc | dB G2 G2 FG | A2 FD Dd- dF | E4 E3 :|
M: 6/8
|: B |E>FE E>FA | B>AF E>FE | F>ED A<FE | F>EF D2 F |
G>FG A>^GA | B<dF B2 A | F<DF A>BF | E3 E2 :|
|: B |E>FG G>AB | dBG G>AG | A>FD D>FG | FAF D2 F |
G>FG A>^GA | B<dF B>AG | F<dF A>BF | E3 E2 :|
ABC
X: 6
T: The Burning Of The Piper's Hut
R: reel
M: 4/4
L: 1/8
K: Emin
|:EFGA B4|BABd B2 AG|FD D2 AD D2|FGAB A2 GF|
EFGA B3 B|BABd B2 AG|FD D2 B2 AG|F2 E2 E3 D:|
|:EFGA BE E2|dE E2 B2 AG|FD D2 AD D2|FGAB A2 GF|
EFGA BE E2|dE E2 B2 AG|FD D2 B2 AG|F2 E2 E3 D:|
|:EB B2 dB B2|EB B2 dBAG|FD D2 AD D2|FA A2 dBAF|
EB B2 dB B2|EB B2 d2 AG|FD D2 B2 AG|FE E2 E2 B2:||
# Added by JACKB .
ABC
X: 7
T: The Burning Of The Piper's Hut
R: reel
M: 4/4
L: 1/8
K: Bmin
|: F |Bcde f4 | f>ef<a f2 ed | c2 A2 e2 A2 | cdef e2 dc |
Bcde f4 | f>ef<a f2 ed | c2 A2 f2 ed |c2 BA B3 :|
|: F |Bcde fB ~B2 | aB ~B2 f2 ed | c2 A2 e2 A2 | cdef e2 dc |
Bcde fB ~B2 | aB ~B2 f2 ed | c2 A2 f2 ed | c2 BA B3 :|
ABC

Thirty-two comments

Burning of the Piper’s Hut

I play this as a slow reel, almost at "air" pace, but I’ve also heard more forcible versions, played as a march or even just a notch below typical session speed (whatever that is) for a reel.

I’ve also played this in Am and in Bm, depending on what other instruments are joining in. I like Em for solo fiddle or D whistle or flute.

This is a bare bones setting. There are lots of places to put cut notes, rolls, even triplets, but the basic melody stands alone just fine. Learn it this way first and it will never let you down.

I’ve heard stories that this tune comes from the mid 1700s when England was actively stomping out the culture of the Scottish Highlands. Piping was illegal for a time. And I’ve heard bad jokes that the tune title came from a fiddler’s wishful thinking….

Posted .

thanks, will! i’d only heard the tune once & didn’t want to learn one of those weird versions that happen when i only half-remember a tune i’ve heard.

your remark about the title being a fiddler’s wishful thinking is very apt. that’s the first thing that a fiddler friend said when i told her the title of the tune …

sarah cardin

Piper’s hut

This tune is actually a 2/4 bagpipe march which has 4 parts and was originally set in the piping equivalent of Bm. It also appears in one collection under the title of "The Defaulter’s March"

Posted by .

The burning of the piper’s hut

This is an old (mid 18th century?) Scottish reel that I have played for years on the fiddle in B minor. I have seen it notated in two books…Robin (Incredible String Band) Williamson’s English, Welsh, Scottish and Irish Fiddle Tunes and The Well Travelled Fiddler’s Collection by Christine Martin and Anne Hughes. Williamson’s setting is two parts which, according to the uillean piper in the band I play in, is pushing it a bit as the B tune is (according to him) identical to the A part from the odd random triplet: and the second setting is in four!! parts which reduced him to hilarity.
Perhaps they were right about pipers.
If you want to hear a recording check out the website of Siansa (the band I play in in London)…www.siansa.com. and there is a 60 second sound bite of this tune played as an air and then a reel. It is a great tune and always gets feet tapping at gigs.

The Burning of the Piper’s Hat

I’ve heard a slightly different version of this tune on a recording by a group called "tiompan" (recorded in Gretna Green), which was actually called "the burning of the piper’s HAT" instead of "hut". I’ll try to put this variation on the site asap. It’s mainly different in it’s second part, but is a fantastic tune. The recording begins very slow and simple with only a hammer dulcimer and slowly builds up adding more chords and instruments and speeds up more and more. I usually play it preceded by an Israeli tune called "Hatikvah", and followed by the melody of "The Raggle Taggle Gypsy"…

4 parts

"ceolachan" has asked me about the other 2 parts of this tune, and I will post them in abc form in the next week or so.
The 4-part version can be found in the Willie Ross Collection Vol.4 or thecollection by the Royal Scottish Piper’s Society. It is called "The Defaulter’s March" in "The Glendaruel Collection" by W.Norris.

Posted by .

Thanks Kenny ~ more pertinent and valued information… I look forward to giving that 4-parter a go…

P.S. ~ what’s the earliest date you have for this tune?

Willie Ross

ceolachan - I tried to find out when Willie Ross’s books were published, using "Google" , and although I haven’t found out yet [ I do have 3 of his books at home, and will check ] - I came across this:

http://www.cl.cam.ac.uk/users/rja14/music/

Haven’t time to check it out at the moment , but looks promising.

The first time I heard this tune was on an LP recorded live at a Breton traditional music festival, possibly Lorient ,in the early 70s, but it’s a good deal older than that. I seem to remember they called it "Marche de la Pluie", which I think was a name made up on the spot because it was raining when they did the live recording.
I’ll try to get on the transcription this weekend.

Posted by .

Basic abcs

Here’s the basic “abcs” for the 4-part version, known as the “Defaulter’s March”. I haven’t bothered to put in the “>” marks to show dotted notes. The additional third and fourth parts don’t really add much to the basic tune, as they’re only minor variations on the first two bars, but it nevertheless may be of interest to some of you.


Bcde f4 | f2 a2 f2 ed | c2 A2 e2 A2 | c2 ef eAcA |
Bcde f4 | f2 a2 f2 ed | c2 A2 f2 c2 |c2 B2 B4 :|
Bcde f2 B2 | a2 B2 f2 ed | c2 A2 e2 A2 | c2 ef eAcA |
Bcde f2 B2 | a2 B2 f2 ed | c2 A2 f2 c2 | c2 B2 B4 :|
Bcde fBce | aBce f2 ed | c2 A2 e2 A2 | c2 ef eAcA |
Bcde fBce | aBce f2 ed | c2 A2 f2 c2 | c2 B2 B4 :|
Bcde fBBB | aBBB fBBB | cAAA eAAA | c2 ef eAcA |
Bcde fBBB | aBBB f2 ed | c2 A2 f2 c2 | c2 B2 B4 :|

Posted by .

Much appreciated Kenny, thanks again. I look forward to anything on the date for it you might dredge up. My curiosity is because this was one of the first tunes I was ever taught, and just my usual unending curiosity and frustration, like not being able to remember who taught it to me or the ‘where’ of it.
:-/

Your 4-part transcription struck a memory ~ I’d first learned this from a piper…

“Ross’s Music Page & the ‘Pastoral Pipes of the 18th Century”

WOW! ~ What a link, as offered by Kenny above, what a treasure trove… Kenny! ~ no, I won’t get all soppy and sentimental here, just another thanks…

It appears as a 2/4 march (The Burning of the Piper’s Hut) in W Ross Book 4, published in 1943.

I was asked to play this tune on the fiddle many moons ago in a workshop given by Aonghas Grant. Aonghas was demonstrating ornamentation and, I guess, my ornamentation was considered interesting (a ‘pipey’ style), though the fiddle wasn’t my main instrument then, and although I should have been flattered, I was bricking it. Aonghas suggested that it was a very old tune and that it related to Highland clearance times, as Will alludes to in the OP. Aonghas does love stories though!

It appears in several collections - usually as a 2/4 march, but there are 6/8 variants. There is a setting, Burning the Piper’s Hut, in Donald MacPhee’s 1876 collection:

X:1
T:Burning The Piper’s Hut
S:MacPhee’s Selection
M:2/4
L:1/8
R:2/4 March
K:Hp
|:f|\
B/c/d/e/ f2|f>a fe/d/|c>A d/eA/|c/d/e/f/ e/A/c/A/|
B/c/d/e/ f2|f>a fe/d/|c>A d/fc/|cB B:|
|:f|\
B/c/d/e/ f>B|a>B fe/d/|c>A d/eA/|c/d/e/f/ e/A/c/A/|
B/c/d/e/ fB|aB fe/d/|c>A d/fc/|cB B:|
|:f|\
B/c/d/e/ f/B/B/B/|a/B/B/B/ fe/a/|c/A/A/A/ e/A/A/A/|\
c/d/e/f/ ed/c/|
B/c/d/e/ f/B/B/B/|a/B/B/B/ fe/d/|c>A d/fc/|cB B:|
|:f|\
B/c/d/e/ f/B/B/B/|a/B/B/B/ f/B/B/B/|c/A/A/A/ e/A/A/A/|\
c/d/e/f/ e/A/c/A/|
B/c/d/e/ f/B/B/B/|a/B/B/B/ fe/d/|c>A d/fc/|cB B:|

There is a 6/8 variant in David Glen’s collection, Book 3, published a wee bit later than MacPhee’s book. Glen attributes it to "A MacKellar", though it is undoubtedly a variant of the 2/4 march:

X:1
T:The Burning of the Piper’s Hut
C:A MacKellar
S:David Glen Book 3
M:6/8
L:1/8
R:6/8 March
K:Hp
|:f|\
B>BB B>ce|f>ef B>cd|c>BA e>cA|c>Bc A>Bc|
d>cd e>de|f>gf f>ed|c<Ac e>fc| B3 B2:|
|:f|\
B>cd d>ef|afd d>cd|e>cA A>Bc|cec A>Bc|
d>cd efg|afd d>cd|e>cA A<ac|B3 B2:|

I’ve left out the gracing, as it is a bit of work, and makes abc notation rather difficult to read. Much as there is reluctance to notate ornamentation in traditional music (often with good reason), it is part of Highland pipe notation (being necessary in separating notes), and does help to give an impression of the lift in the music. I might be persuaded to put them in by those who don’t wince at the thought.

To grace or not to grace ~

Weejie, the ‘comments’ are the place for giving transcriptions with gracing, but it also helps to balance it if you also give it raw and unadulterated, which is usually what is appreciated in initial contributions, as most of us don’t play the highland bagpipes… ;-)

A different tune ~ a 6/8 march

Thanks for the link to the audio. However, your MacKeelar tune from "The David Glen, Bk. 3" is not the same tune here, despite sharing the title. And, I know it, but I don’t think as the title "The Burning of the Piper’s Hut". At the moment it’s only "I know this!" But, if it isn’t here already, why not add it to the database, with some history, and hopefully your way with it, and then you could add a version in the ‘comments’ with the full gracings?

I wouldn’t submit a tune in the main part with GHB gracing, Ceol.
However, as you’ll always hear the pipes with gracing, it’s how fiddlers hear pipe tunes - and how pipe tunes evolve into fiddle tunes. The skeleton doesn’t always transfer well. Fiddlers would hear the gracing as part of the whole, and pipe gracings evolve into fiddle ornaments. This particular tune is a fine example. That "c>A d/fc/" motif makes more sense when heard as "{dcd}c3/2{e}A/ {G}d/{G}ec/". At least, it does to someone reared on Scottish trad.
I think you’ll find that I’ve submitted a few pipe tunes in "raw" mode and then presented the graced versions. Some people might take offence at the suggestion that the pipe settings are adulterated. It’s how they were when God created them.

""The David Glen, Bk. 3" is not the same tune here, "

I think it is a variant. Doctored and thrown about, but I can hear the link.

Error - meant to show ungraced "c>A d/fc/"
graced "{dcd}c3/2{e}A/ {G}d/{G}fc/"

6/8 march

That’s different enough, I think… And as to ‘gracings’, I don’t mean as the main submission but in the ‘comments’, which would interest not just GHB pipers… It is only a suggestion. Sometimes a variation is significant. While a change of key isn’t, a 6/8 march is, and being a fan of 6/8 marches, I think this one deserves a place of its own, with a link back here of course… But it’s your choice. However, as I’m now playing this, if you don’t, I will. :-P

I’ve played a version of "Burning of the Piper’s Hut", as given originally, for a very long time… It’s an old favourite…

I did get the ‘similarity’, or family resemblance…

It might deserve a separate submission, It’s actually a cracking tune, whether it is a bastardisation or not. Feel free to submit it yourself. If not, I’ll consider it myself sometime. My brain is too puddled at present. Helping a friend with immigration problems from the US.

Yeah, I’d been playing it for some time in a more familiar setting even before Aonghas pounced on me - with gracing though - that’s why Aonghas pounced on me.

And Aonghas pounced on me about 28 years ago!

This march has some personal attachments to it, as an uilleann piper I knew actually had his house blown up, burned to the ground, because he had offered his excellent hospitality to a couple of curious GHB pipers from an ‘occupying’ Scottish regiment, this being in ‘The North’. He’d opened his door and shared sup and music with them. Fortunately, it wasn’t his main house the begrudgers of extreme political persuasions laid waste to. They’re still a scary lot, both sides of that argument…

Here’s a rough out of how I’ve tended to play this, just the basics. It’s not far off the original submitted by Will, and to make it an easier comparison, and keep the ‘black’ to a minimum, like him I’ll also do it in 4/4. I’ll then add a version of the 6/8 Weejie has offered above, but altered to fit. 8-)


X: 5
T: Burning Of The Piper’s Hut, The
M: 4/4
L: 1/8
R: reel
K: Emin
|: D |\
E>FGA B2 B^A | B>^ABd B2 AG | F2 D2 A2 D2 | FGAB AB/A/ GF |
E>FGA B2 B^A | B>^ABd B2 AG | F2 D2 Bc/B/ AG | F2 E^D E3 :|
|: B |\
EFGA BEE/E/E | dEE/E/E Bc/B/ AG | F2 D2 A2 D2 | FGAB A2 GF |
EFGA BEE/E/E | dEE/E/E B2 AG | F2 D2 B2 AG | FG/F E^D E3 :|

6/8 to 4/4 to a 6/8 in memory

X: 6
T: Burning Of The Piper’s Hut, The
M: 6/8
L: 1/8
R: reel
K: Emin
|: B |\
E>EE E>FA | B>AB E>FG | F>ED A>FD | F>EF D>EF |
G>FG A>GA | B>cB B>AG | F<DF A>BF | E3 E2 :|
|: B |\
E>FG G>AB | dBG G>FG | A>FD D>EF | FAF D>EF |
G>FG ABc | dBG G>FG | A>FD D<dF | E3 E2 :|

X: 7
T: Burning Of The Piper’s Hut, The
M: 4/4
L: 1/8
R: reel
K: Emin
|: B |\
E2 EE E2 FA | B2 AB E2 FG | F2 ED A2 FD | F2 EF D2 EF |
G2 FG A2 GA | B2 cB B2 AG | FD- DF A2 BF | E4 E3 :|
|: B |\
E2 FG G2 AB | dB G2 G2 FG | A2 FD D2 EF | FA F2 D2 EF |
G2 FG ABc | dB G2 G2 FG | A2 FD Dd- dF | E4 E3 :|

X: 8
T: ?
M: 6/8
L: 1/8
R: reel
K: Emin
|: B |\
E>FE E>FA | B>AF E>FE | F>ED A<FE | F>EF D2 F |
G>FG A>^GA | B<dF B2 A | F<DF A>BF | E3 E2 :|
|: B |\
E>FG G>AB | dBG G>AG | A>FD D>FG | FAF D2 F |
G>FG A>^GA | B<dF B>AG | F<dF A>BF | E3 E2 :|

From memory, this last one could be me mixing a couple of similar tunes up? :-/

The A MacKellar to whom that 6/8 march is attributed was apparently PM Alexander MacKellar, who is believed to have composed "The Barren Rocks of Aden". Save any further info for possible separate submission.

The Myth of Banning of the Pipes

Several modern scholars, first and foremost John Gibson in "Traditional Gaelic Bagpiping", have researched the issue at great length. The pipes were never banned, although the myth persists to this day.

Cheers

Matt

"Several modern scholars, first and foremost John Gibson in "Traditional Gaelic Bagpiping", have researched the issue at great length. The pipes were never banned, although the myth persists to this day."

I think you mean that "several modern scholars including John Gibson [in cited volume] argue that the pipes were never banned".

X: 7 “Burning the Piper’s Hut” - march

Another transcription taken from a recently uncovered collection in our collections: "Guest Musician Manual: Evergreen Folkways" - page 54… There’s a little information about this collection in the comments for an earlier submission ~
http://thesession.org/tunes/13723