Download ABC

DFMontgomery’s tunebook: marchs

Order by name, newest, oldest.

The Blackbird From Clough

X: 1
T: The Blackbird From Clough
R: march
M: 4/4
L: 1/8
K: Gmaj
gfgA B2BA|B2BA Bddf|gfgA B2ef|gfed efgz|
gfgA B2BA|B2BA Bddf|gfgA B2ef|1 gfed e4:|2 gfed e3B||
edef g2fg|afdf afed|edef g2fg|afed e3B|
edef g2fg|afdf a2ga|bgaf gfef|1 gfed e3B:|2 gfed e3z||
X: 2
T: The Blackbird From Clough
R: march
M: 4/4
L: 1/8
K: Bmin
|:B>c|d2 d>E F2 F>^E|F2 F>E F<AA>c|d2 d>E F2 (3ABc|d>cB<^A B2:|
B>^A|B>AB>c d2 c>d|e>c (3ABc e>cB>^A|B>A (3ABc (3ded c>d|e>cB<c B2 B>^A|
B>AB>c d2 c>d|e>cA>c e2 (3cde|f>Ae>A d2 (3cBA|d>cB<^A B2||
X: 3
T: The Blackbird From Clough
R: march
M: 4/4
L: 1/8
K: Dmaj
dcdE F2FE|F2FE FAAc|dcdE F2Bc|dcBA Bcdz|
dcdE F2FE|F2FE FAAc|dcdE F2Bc|1 dcBA B4:|2 dcBA B3F:|
BABc d2cd|ecAc ecBA|BABc d2cd|ecBA B3F|
BABc d2cd|ecAc e2de|fdec dcBc|1 dcBA B3F:|2 dcBA B3z:|

Bó Mhín Na Toitean

X: 1
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Ador
A2 e2 e2 dB|d2 ef ge a2|A2 e2 e2 dB|eg ed BA GB|
A2 e2 e2 dB|d2 ef ge a2|eg ed e/f/g ed|B2 A2 A2 BG:|
A2 a2 a2 ge|d2 ef ge a2|A2 a2 a2 ge|dg ed BA GB|
A2 a2 a2 ge|d2 ef ge a2|eg ed e/f/g ed|B2 A2 A2 BG:|
X: 2
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Ador
A2 e2 e2 dB|d2 ef ge a2|A2 e2 e2 dB|g2 ed B2 AG|
A2 e2 e2 dB|d2 ef ge a2|ge dB e/f/e fd|ef dB A3 G|
A2 e2 e2 dB|d2 ef ge a2|A2 e2 e/f/e dB|g2 ed B/c/B AG|
A2 e2 e2 dB|d2 ef ge a2|ge dB g2 ed|B2 A2 A2||
A2 a2 a2 ge|d2 ef ge a2|A2 a2 a2 ge|dg ed B/c/B A2|
A2 a2 a2 ge|d2 ef ge a2|ge dB g2 ed|B/c/B A2 A2:|
A2 e2 e2 dB|d2 ef ge a2|A2 e2 e2 dB|d2 ed B2 A2|
A2 e2 e2 dB|d2 ef ge a2|ge dB g2 ed|B2 A2 A2 BG|
A2 e2 e2 dB|d2 ef ge a2|A2 e2 e2 dB|g2 ed B2 AG|
A2 e2 e2 dB|d2 ef ge a2|ge dB g2 ed|B2 A2 A2||
A2 a2 a2 ge|d2 ef ge a2|A2 a2 a2 ge|dg ed B/c/B A2|
A2 a2 a2 ge|d2 ef ge a2|ge dB g2 ed|B/c/B A2 A2:|
A2 e2 e2 dB|d2 ef ge a2|A2 e2 e2 dB|g2 ed B2 AG|
A2 e2 e2 dB|d2 ef ge a2|ge dB e2 fd|ef dB A3 G||
X: 3
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Gmaj
A2e2 e2dB|d2ef ge(ga)|{Ad}A2e2 e2dB|(fg)ed {Bd}B2AG|
{Ad}A2e2 e2dB|d2ef ge(ga)|{ga}gedB (e2f)d|efdB {Ad}A2BG:|
A2a2 a2ge|d2ef ge(ga)|A2a2 a2ge|dged {Bd}B2AG|
A2a2 a2ge|d2ef ge(ga)|{ga}gedB (e2f)d|efdB A2BG:|
X: 4
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Ador
|:A2 e2 ~e2 dB|d2 ef ge !slide!a2|A2 e2 ~e2 dB|eg ed ~B2 AG|
A2 e2 ~e2 dB|d2 ef ge !slide!a2|eg ed (3efg ed|B2 A2 {c/}A2 BG:|
|:A2 a2{c'/}a2 ge|d2 ef ge !slide!a2|A2 a2 {c'/}a2 ge|dg ed ~B2 AG|
A2 a2 {c'/}a2 ge|d2 ef ge !slide!a2|eg ed (3efg ed|B2 A2 {c/}A2 BG:|
X: 5
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Edor
|:E2B2 B2AF|A2Bc dB(de)|E2B2 B2AF|(cd)BA F2ED|
E2B2 B2AF|A2Bc dB(de)|dBAF (B2c)A|BcAF E2FD:|
|:E2e2 e2dB|A2Bc dB(de)|E2e2 e2dB|AdBA F2ED|
E2e2 e2dB|A2Bc dB(de)|dBAF (B2c)A|BcAF E2FD:|
X: 6
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Dmix
|:D2A2 A2GE|G2 AB cA d2|D2A2 A2GE|dcAG EAGE|
D2A2 A2GE|G2 AB cA d2|cAGE AcGE|E2 D2 DE =FE:|
|:D2 d2 d2 cA|G2 AB cA d2|D2d2 d2cA|dcAG EAGE|
D2d2 d2cA|G2 AB cA d2|cAGE AcGE|E2 D2 DE =FE:|
X: 7
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Dmix
|:D2A2 A2GE|G2 AB cA d2|D2A2 A2GE|dcAG EAGE|
D2A2 A2GE|G2 AB cA d2|cAGE AcGE|E2 D2 DE =FE:|
|:D2 d2 d2 cA|G2 AB cA d2|D2d2 d2cA|dcAG EAGE|
D2d2 d2cA|G2 AB cA d2|cAGE AcGE|E2 D2 DE =FE:|
X: 8
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Edor
|:E2B2 B2AF|A2 Bc dB e2|E2B2 B2AF|edBA FBAF|
E2B2 B2AF|A2 Bc dB e2|dBAF BdAF|F2 E2 EF =GF:|
|:E2 e2 e2 dB|A2 Bc dB e2|E2e2 e2dB|edBA FBAF|
E2e2 e2dB|A2 Bc dB e2|dBAF BdAF|F2 E2 EF =GF:|
X: 9
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Gmix
|:G2d2 d2cA|c2 de fd g2|G2d2 d2cA|gfdc AdcA|
G2d2 d2cA|c2 de fd g2|fdcA dfcA|A2 G2 GA =BA:|
|:G2 g2 g2 fd|c2 de fd g2|G2g2 g2fd|gfdc AdcA|
G2g2 g2fd|c2 de fd g2|fdcA dfcA|A2 G2 GA =BA:|
X: 10
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Amix
|:A2e2 e2dB|d2 ef ge a2|A2e2 e2dB|aged BedB|
A2e2 e2dB|d2 ef ge a2|gedB egdB|B2 A2 AB =cB:|
|:A2 a2 a2 ge|d2 ef ge a2|A2a2 a2ge|aged BedB|
A2a2 a2ge|d2 ef ge a2|gedB egdB|B2 A2 AB =cB:|
X: 11
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Ador
A2 e2 e2 dB|d2 ef ge a2|A2 e2 e2 dB|de dB GA BG|
A2 e2 e2 dB|d2 ef ge a2|ge de g2 ed|B2 A2 A2 z2:|
a2 a2 a2 ge|d2 ef ge a2|a2 a2 a2 ge|dg ed BA GB|
a2 a2 a2 ge|d2 ef ge a2|ge de g2 ed|B2 A2 A2 z2:|
X: 12
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Amix
|:A2 e2 e2 dB|d2 ef ge a2|A2 e2 e2dB|eged (3Bcd BG|
A2 e2 e2 dB|d2 ef (3gfe a2|(3efg dB (3efg dB|B2 A2 A2 BG:|
|:A2 a2 a2 ge|d2 ef (3gfe a2|A2 a2 a2 ge|dged (3Bcd BG|
A2 a2 a2 ge|d2 ef ge a2|(3efg dB (3efg dB|B2 A2 A2 BG|
A2 a2 a2 ge|d2 ef (3gfe a2|A2 a2 a2 ge|(3efg dB (3efg dB|
A2 a2 a2 ge|d2 ef (3gfe a2|eged (3efg dB|BAAG A2 BG||
X: 13
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Amix
|:A2 e2 e2 dB|d2 ef ge a2|A2 e2 e2dB|eged (3Bcd BG|
A2 e2 e2 dB|d2 ef (3gfe a2|(3efg dB (3efg dB|B2 A2 A2 BG:|
|:A2 a2 a2 ge|d2 ef (3gfe a2|A2 a2 a2 ge|dged (3Bcd BG|
[1A2 a2 a2 ge|d2 ef ge a2|(3efg dB (3efg dB|B2 A2 A2 BG:|
[2A2 a2 a2 ge|d2 ef (3gfe a2|eged (3efg dB|BAAG A2 BG||
X: 14
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Ador
|:A2 e2 e2 d>B|d2 e>f g>e a2|A2 e2 e2 d>B|d2 e>d B2 A>G|
A2 e2 e2 d>B|d2 e>f g>e a2|e/f/g e>d B>e d>e|1 B2 A2 A3 G:|2 B2 A2 A>G B>G||
|:A2 a2 a2 g>e|d2 e>f g>e a2|~a2- a>b a2 g>e|de ed B2- (3BAG|
A2 a2 a2 g>e|d>g e>f g>e a2|e/f/g e>d B>e d>e|1 B2 A2 A>G B>G:|2 B2 A2 A3 G||
X: 15
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Ador
|:A2 e2 e2 dB|d2 ef ge ga|A2 e2 e2 dB|dg ed B2 AG|
A2 e2 e2 dB|d2 ef ge ga|ge dB e2 fd|ef dB A2 AG:|
|:A2 a2 a2 ge|d2 ef ge ga|A2 a2 a2 ge|dg ed B2 AG|
A2 a2 a2 ge|d2 ef ge ga|ge dB e2 fd|ef dB A2 AG:|
|:A2e2 e2dB|d2 ef ge a2|A2e2 e2dB|aged BedB|
A2e2 e2dB|d2 ef ge a2|gedB egdB|B2 A2 AB =cB:|
|:A2 a2 a2 ge|d2 ef ge a2|A2a2 a2ge|aged BedB|
A2a2 a2ge|d2 ef ge a2|gedB egdB|B2 A2 AB =cB:|
X: 16
T: Bó Mhín Na Toitean
R: march
M: 4/4
L: 1/8
K: Ador
|:A2 e2 e2 dB|d2 ef ge a2|A2 e2 e2 dB|eg ed BA GB|
A2 e2 e2 dB|d2 ef ge a2|ge dB g2 ed|B2 A2 A2 BG:|
|:A2 a2 a2 ge|d2 ef ge a2|A2 a2 a2 ge|dg ed BA GB|
A2 a2 a2 ge|d2 ef ge a2|ge dB g2 ed|B2 A2 A2 BG:|

Bonaparte Crossing The Rhine

X: 1
T: Bonaparte Crossing The Rhine
R: march
M: 4/4
L: 1/8
K: Ador
EG|A2 AB AGE2|cdec d2 eg|aged cded|cAGE G2 cB|
A2 AB AGE2|cdec d2 eg|aged cAGE|A2 A2 A2:|
eg|aged cdeg|agec d2 eg|aged cded|cAGE G2 EG|
A2 AB AGEG|cdec d2 eg|aged cABG|A2 (3cBG A2:|
X: 2
T: Bonaparte Crossing The Rhine
R: march
M: 4/4
L: 1/8
K: Dmix
A|D>D DE DCCD|F>G AF G2 (3ABc|d>c AG AGED|C>C CD C2 (3AGE|
D>D DE DCCD|F>G AF G2 (3ABc|d>c AG AGEC|D4 D2 AB|
d>c AG F>G AB|c>d cA c2 (3ABc|d>c AG AGED|C>C CD C2 (3AGE|
D>D DE DCCD|F>G AF G2 (3ABc|d>c AG AGEC|D4 D4||
X: 3
T: Bonaparte Crossing The Rhine
R: march
M: 4/4
L: 1/8
K: Dmix
A2|D>D DE DCCD|F>G AF G2 (3ABc|d>c AG AGED|C>C CD C2 (3AGE|
D>D DE DCCD|F>G AF G2 (3ABc|d>c AG AGEC|D4 D2||
AB|d>c AG F>G AB|c>d cA c2 (3ABc|d>c AG AGED|C>C CD C2 (3AGE|
D>D DE DCCD|F>G AF G2 (3ABc|d>c AG AGEC|D4 D2||
X: 4
T: Bonaparte Crossing The Rhine
R: march
M: 4/4
L: 1/8
K: Ador
|:E>G|A2 A>B A>GE<G|c>d (3edc d2 e>g|a>ge>d (3cBA B>A|G>AG<E G2 c>B|
A2- AB AG (3EFG|c2 e>c (3ddd (3efg|a>ge<d c>AG<E|A2 A>^G A2:|
|:e<g|a>g (3eed c>de>f|g>ag<e g2 c’>b|a>ge>d c2 (3cBA|G2- G>E G2 (3EFG|
(3AAA A>B A>G (GGG|c<de>c d2 (3efg|a2 (3ged c2 B<G|(3AAA A<^G A2:|
X: 5
T: Bonaparte Crossing The Rhine
R: march
M: 4/4
L: 1/8
K: Amix
A>G AB|AG GA|c>d ec|d2 ef/g/|a>g ed|ed BA|G>A BA|G2 ed/B/|
A>G AB|AG GA|c>d ec|d2 ef/g/|a>g ed|ed BA/G/|A3 B|1 A2 ed/B/:|2 A2 ef/g/||
a>g ed|ed ef|g>a ge|g2 ef/g/|a>g ed|ed BA|G>A BA|G2 ed/B/|
A>G AB|AG GA|c>d ec|d2 ef/g/|a>g ed|ed BA/G/|A3 B|1 A2 ef/g/:|2 A2 ed/B/||
X: 6
T: Bonaparte Crossing The Rhine
R: march
M: 4/4
L: 1/8
K: Ador
|:E>G|A2 A>B A>GE>D|c>de>c d2 e>g|a>ge>d c>AG>E|G>Ec>E G2 E>G|
A2 A>B A>GE>D|c>de>c d2 e>g|a>ge>d c>AG>E|A2 A>A A2:|
|:eg|a>ge>d c>de>f|g>ea>f g2 e>g|a>ge>d c>AG>E|G>Ec>E G2 E>G|
c>AB>G A>GE>D|c>de>c d2 e>g|a>ge>d c>AG>E|A2 A2 A2:|
X: 7
T: Bonaparte Crossing The Rhine
R: march
M: 4/4
L: 1/8
K: Dmaj
FG|:"D" [FA]B AF [F2A2] de|fefa [A2d2] dc|"G" BcdB "D" AFDF|
"A" E2 E>F E2 FG|"D" [FA]B AF [F2A2] de|fefa [A2d2] dc|
"G" BcdB "D" AF "A"EF|1 "D" D2 DE D2 FG:|2 "D" D2 DE D2 de||
|:"D" fefg [A2a2] aA|"G" [GB]A Bc "D" [A3d3] A|"G" [GB]c dB "D" AFDF|
"A" E2 E>F E2 FG|"D"[FA]B AF [F2A2] de|[Af]e fa [A3d3] d|
"G" B>c dB "D" AF "A"EF|1 "D" D2 D>E DAde:|2 "D" D2 D>E [D4A4]||

Chanter’s Tune

X: 1
T: Chanter's Tune
R: march
M: 4/4
L: 1/8
K: Dmix
DD AG/E/|DD cB/c/|dA AG/E/|cB/c/ AG/E/|
DD AG/E/|DD cB/c/|dA AG/E/|D2 D2:|
|:A>B cB/c/|A/G/A/B/ cB/c/|dA AG/E/|cB/c/ AG/E/|
DD AG/E/|DD cB/c/|dA AG/E/|D2 D2:|
X: 2
T: Chanter's Tune
R: march
M: 4/4
L: 1/8
K: Ddor
|:D2 D2 A2 GE|D2 D2 c2 Bc|d2 A2 A2 GA|c2 Bc AGFE|
D2 D2 A2 GE|D2 D2 c2 Bc|d2 A2 AGFE|D4 D4:|
|:A3 B c3 B|AGAB c2 Bc|d2 A2 A2 GA|c2 Bc AGFE|
D2 D2 A2 GE|D2 D2 c2 Bc|d2 A2 AGFE|D4 D4:|
X: 3
T: Chanter's Tune
R: march
M: 4/4
L: 1/8
K: Ddor
|:DD AG/E/|DD cB/c/|dA AG/A/|cB/c/ A/G/F/E/|
DD AG/E/|DD cB/c/|dA AG/A/|D2 D2:|
|:A>B c>B|A/G/A/B/ cB/c/|dA AG/A/|cB/c/ A/G/F/E/|
DD AG/E/|DD cB/c/|dA A/G/F/E/|D2 D2:|
X: 4
T: Chanter's Tune
R: march
M: 4/4
L: 1/8
K: Amix
A2A2 e2dB|A2A2 g2fg|a2e2 e2dB|g2fg e2dB|
A2A2 e2dB|A2A2 g2fg|a2e2 e2dB|A4 A4:|
edef g2fg|edef g2fg|a2e2 e2dB|g2fg e2dB|
A2A2 e2dB|A2A2 g2fg|a2e2 e2dB|A4 A4:|
X: 5
T: Chanter's Tune
R: march
M: 4/4
L: 1/8
K: Ador
A2{c/}A2 ~e2dB|{c/}AG{c/}A2 ~g g{a/}g|a2e2 ~e2dB|!slide!g2fag ed/c/B/|
A2{c/}A2 ~e2dB|{c/}AG{c/}A2 ~g g{a/}g|a2e2 ~e2dB|1 A2 {c/}AGAGEG:|2 A2 {c/}AGA4||
{a/}edef ~g2fg|{a/}edef ~g2fg|gae2 ~e2dB|g2fag ed/c/B/|
A2{c/}A2 ~e2dB|{c/}AG{c/}A2 ~g g{a/}g|a2e2 ~e2dB|A2 {c/}AGA4:|
X: 6
T: Chanter's Tune
R: march
M: 4/4
L: 1/8
K: Emix
EE BA/F/|EE dc/d/|eB BA/F/|dc/d/ BA/F/|
EE BA/F/|EE dc/d/|eB BA/F/|E2 E2:|
|:B>c dc/d/|B/A/B/c/ dc/d/|eB BA/F/|dc/d/ BA/F/|
EE BA/F/|EE dc/d/|eB BA/F/|E2 E2:|
X: 7
T: Chanter's Tune
R: march
M: 4/4
L: 1/8
K: Dmix
DD AG/E/|DD cB/c/|dA AG/E/|cB/c/ AG/E/|
DD AG/E/|DD cB/c/|dA AG/E/|D2 D2:|
|:AA/B/ cB/c/|A/G/A/B/ cB/c/|dA AG/E/|cB/c/ AG/E/|
DD AG/E/|DD cB/c/|dA AG/E/|D2 D2:|
X: 8
T: Chanter's Tune
R: march
M: 4/4
L: 1/8
K: Dmix
D2D2 A2GE|D2D2 c2Bc|d2A2 A2GE|c2Bc A2GE|
D2D2 A2GE|D2D2 c2Bc|d2A2 A2GE|D4 D4:|
|:A2>B2 c2Bc|AGAB c2Bc|d2A2 A2GE|c2Bc A2GE|
D2D2 A2GE|D2D2 c2Bc|d2A2 A2GE|D4 D4:|
X: 9
T: Chanter's Tune
R: march
M: 4/4
L: 1/8
K: Amix
|:AA ed/B/|AA gf/g/|ae ed/B/|gf/g/ ed/B/|
AA ed/B/|AA gf/g/|ae ed/B/|A2 A2:|
|:ee/f/ gf/g/|e/d/e/f/ gf/g/|ae ed/B/|gf/g/ ed/B/|
AA ed/B/|AA gf/g/|ae ed/B/|A2 A2:|

The Devil Is Dead

X: 1
T: The Devil Is Dead
R: march
M: 4/4
L: 1/8
K: Gmaj
D2DE GABA|GE~E2 cEGE|D2DE GABc|1 dedB (3ABA GE:|2 dedB (3ABA G2||
|:d2dc Bcd2|e2ed cde2|d2dc BcdB|1 GABG (3ABA GB:|2 GABG (3ABA GE||
"variations"
|:D2DE GABA|GE~E2 cEGE|D2DE GABc|1 dedB (3ABA GE:|2 dedB (3ABA GB||
d2dc Bcd2|e2ed cde2|d2dc BcdB|GABG A2GB|
d2dc Bcd2|e2ed cdec|degd egdB|GABG A2GE||
X: 2
T: The Devil Is Dead
R: march
M: 4/4
L: 1/8
K: Amaj
|:E2 EF ABcB|A~F3 dFAF|~E3F ABcf|1 efec (3BcB AF:|2 efec (3BcB A2||
e2 ed cd e2|ef{a}fe fgaf|efed cdec|ABcA B2 Ac|
e2 ed cd e2|ef{a}fe fgaf|e~a3 f2 ec|ABcA (3BcB AF||
X: 3
T: The Devil Is Dead
R: march
M: 4/4
L: 1/8
K: Gmaj
|:G>E|(3DDD D>E G>AB>A|G>E (3EEE c>EG>E|(3DDD D>E G>AB>c|d>ed>B A2:|
G2|d2 d>c B>c d2|e2 e>d c>d e2|(3ddd d>c B>cd>B|G>A (3BAG (3AAA G2|
d2 d>c B>c d2|(3eee e>d e>f g2|d2 g>d (3efg d>B|G>A (3BAG A2||
X: 4
T: The Devil Is Dead
R: march
M: 4/4
L: 1/8
K: Dmaj
A/G/|F>A A>B d>e f>d|B/B/B B>A d<c B>A|F>A A>B d>e f>d|g>e f<d e2 d:|
g|f<a a>f d>f a<f|g/g/g g>f g>a (3bag|f<a a>f d>f a>f|g>b f/a/f e2 d>g|
f<a a>f d>f a<f|g/g/g g>f g>a (3bag|f<a a>f d>f a>f|g>b f/a/f e2 d<B||
e/e/e e>f g>e f>d|B/B/B B>A d<c B>A|F>A A>B d>e f>d|g>e f<d e2 d<B|
e/e/e e>f g>e (3fed|B/B/B B>A d<c B>A|F>A A>B d>e f<d|g>b f/a/f e2 d||
G|F>A A>F D>B A>F|E/E/E E>F G>B (3BAG|F>A A>F A<B A>F|G<B A<F E2 D>G|
F>A A>F D>B A>F|E/E/E E>F G>B (3BAG|F<A A>B d>f a<f|g>b f/a/f e2 d||
X: 5
T: The Devil Is Dead
R: march
M: 4/4
L: 1/8
K: Dmaj
|:A<FA>B d>gf>e|d2B>G d>GB>G|A2F>A d>ef>a|1 g2f>g e2d>B:|2 g2f>g e2d2||
|:f<aa>f d>fa>f|g2b>g d>gb>g|a2a>f d>ef>a|1 (3gab f>g e2d2:|2 (3gab f>g e2d>B||
X: 6
T: The Devil Is Dead
R: march
M: 4/4
L: 1/8
K: Dmaj
F<A A>B d>e f>e|d<B B>A B<d B>A|F<A A>B d>e f>d|e<g f<a e2 d2:|
f<a a>g f>d a>f|g<b b>a g>e b>g|f<a a>g f>d a>f|g<b f<a e2 d2:|
e<e e>f g>f e<d|B2 B>A B<d B>A|F<A A>B d>e f>d|e<g f<a e2 d2:|
F<A A>G F>D A>F|G<B B>A G>E B>G|F<A A>G F>D A>F|G<B A>F E2 D2|
F<A A>G F>D A>F|E<E E>F G>F E>D|F<A A>B d>e f>g|a>b a<f e2 d2||

Doctor Ross’s 50th Welcome To The Argyllshire Gathering

X: 1
T: Doctor Ross's 50th Welcome To The Argyllshire Gathering
R: march
M: 4/4
L: 1/8
K: Amix
|:e|A>ce c<Ac|e>fe c2 A|c<ee e>cA|B<dc B2 G|
A>ce c<Ac|e>fe c2 A|c<ee e>dB|A3 A2:|
g|a>Aa A>ce|e>ca c2 A|a>ed c<Ac|B<dc B2 g|
a>Aa A>ce|e>ca c2 A|c<ee e>dB|A3 A2 g|
a>Aa A>ce|e>ca c2 A|a>ed c<Ac|B/c/dg B2 G|
A>ce c<Ac|e>fe c2 A|c<ee e>dG|A3 A2||
|:E|A>BA c2 d|e<ae c2 A|e>AB c2 e|B<dc B2 G|
A>BA c2 d|e<ae c2 A|c<ee e>dB|A3 A2:|
g|a>AA e>AA|e>ca c>AA|c<ea e>cA|B/c/dg B2 g|
a2 A e2 A|e<ca c2 A|c<ee e>dB|A3 A3|
a>AA e>AA|e>ca c>AA|c<ea e>AA|B<dg B2 =c|
A>Bc BB/c/d|c<ea c2 A|c2 e e>dG|A3 A2||
X: 2
T: Doctor Ross's 50th Welcome To The Argyllshire Gathering
R: march
M: 4/4
L: 1/8
K: Amix
|:e|A>ce c<Ac|e>fe c2 A|c<ee e>cA|B<dc B2 G|
A>ce c<Ac|e>fe c2 A|c<ee e>dB|A3 A2:|
|:g|a2 a A>ce|e>ca c2 A|a>ed c<Ac|B<dc B2 G|
A>ce c<Ac|e>fe c2 A|c<ee e>dB|A3 A2:|
|:e|A2 A c2 d|e>fe c2 A|e2 A c2 e|B<dc B2 G|
A2 A c2 d|e>fe c2 A|c<ee e>dB|A3 A2:|
|:g|a2 A e2 A|e>ca c2 A|c<ea e>cA|B<dg B2 G|
A>Bc B>cd|c<ea c2 A|c<ee e>dB|A3 A2:|
X: 3
T: Doctor Ross's 50th Welcome To The Argyllshire Gathering
R: march
M: 4/4
L: 1/8
K: Amix
e3- e2 A|:A>ce c<Ac|e>fe c2 A|c<ee e>cA|B<dc B2 G|
A>ce c<Ac|e>fe c2 A|c<ee e>dB|1 A3 A2 e:|2 A3 A2||
g|a2 A A>ce|e>ca c2 A|a>ed c<Ac|B<dc B2 g|
a2 A A>ce|e>ca c2 A|c<ee e>dB|A3 A2 g|
a2 A A>ce|e>ca c2 A|a>ed c<Ac|B<dc B2 G|
A>Bc B>cd|c<ea c2 A|c<ee e>dB|A3 A2||
|:e|A2 A c2 d|e>fe c2 A|e2 A c2 e|B<dc B2 G|
A2 A c2 d|e>fe c2 A|c<ee e>dB|A3 A2:|
g|a2 A e2 A|e>ca c2 A|c<ea e>cA|B<dc B2 g|
a2 A e2 A|e>ca c2 A|c<ee e>dB|A3 A2 g|
a2 A e2 A|e>ca c2 A|c<ea e>cA|B<dc B2 G|
A>Bc B>cd|c<ea c2 A|c<ee e>dB|A3- A2||
X: 4
T: Doctor Ross's 50th Welcome To The Argyllshire Gathering
R: march
M: 4/4
L: 1/8
K: Amix
|:e|A>ce c<Ac|e>fe c2 A|c<ee e>cA|B<dc B2 G|
A>ce c<Ac|e>fe c2 A|c<ee e>dB|A3 A2:|
|:g|a>ga A>ce|e>ca c2 A|a>ed c<Ac|B<dc B2 G|
[1 a>ga A>ce|e>ca c2 A|c<ee e>dB|A3 A2:|
[2 A>ce c<Ac|e>fe c2 A|c<ee e>dB|A3 A2||
|:e|A>GA c2 d|e>fe c2 A|e>GA c2 e|B<dc B2 G|
A>GA c2 d|e>fe c2 A|c<ee e>dB|A3 A2:|
g|a>GA e>GA|e>ca c2 A|c<ea e>cA|B<dg B2 G|
a>GA e>GA|e>ca c2 A|c<ee e>dB|A3 A2 g|
a>GA e>GA|e>ca c2 A|c<ea A>ce|B<dg B2 G|
A>Bc B>cd|c>ea c2 A|c<ee e>dB|A3 A2||

John O’Shea’s

X: 1
T: John O'Shea's
R: march
M: 4/4
L: 1/8
K: Gmaj
|:BA|G2 B,C D2 E/F/G|A3 B d2 BA|G>E DE G2 G2|G6 AB|
c3 d e2 dc|B2 G2 A2 Bc|dc BG FD E^C|D6 A>B|
c2 cd e2 dc|B3 G A2 Bc|d>c BG F>D E^C|D6 BA|
G2 B,C D2 EG|A3 B d2 BA|GE DE G2 G2|G6:|
X: 2
T: John O'Shea's
R: march
M: 4/4
L: 1/8
K: Dmaj
|:g/f/e|d2 FG A2 Bd|e2 ef a2 fe|dB AB d2 e2|d6 d/e/f|
g3 a bc'/b/ ag|f2 d2 e2 fg|ag f/e/d cA B/A/^G|A6 ef|
g>d ga b2 ag|f2 d2 e2 fg|ag fd cA B^G|A>B AG A2 fe|
d2 fg a2 B/c/d|e3 f ab/a/ fe|d>B AB d2 c2|d6:|
X: 3
T: John O'Shea's
R: march
M: 4/4
L: 1/8
K: Amaj
|:cB|A2 cd e2 FG/A/|B3 c e2 cB|AF EF A2 G2|A6 Bc|
d3 e f2 ed|c2 A2 B2 cd|e/f/e/d/ cA G/A/G/E/ F^D|E6 Bc|
d2 Ad f2 ed|c2 Ac e2 B/c/d|ed cA GE F/E/^D|E2 ^D2 E2 cB|
A2 CD E2 F/G/A|B3 c e2 cB|AF EF A2 A2|A6:|
X: 4
T: John O'Shea's
R: march
M: 4/4
L: 1/8
K: Gmaj
|:cBA|G2 B2 D2 EG|A>^GAB d2 BA|GEDE G2 G2|G6 AB|
c3 d e2 dc|B2 G2 A2 Bc|d2 AG F/G/A EA|D2 D>E D2 AB|
c3 d e2 dc|B2 G2 A2 Bc|d2 AG F/G/A EA|D2 D>E DcBA|
G2 B2 D2 E/F/G|A>^GAB d2 BA|GEDE G2 G2|G4- G:|
X: 5
T: John O'Shea's
R: march
M: 4/4
L: 1/8
K: Dmaj
|:gfe|d2 F2 A2 Bd|e>^def a2 fe|dBAB d2 d2|d6 ef|
g3 a b2 ag|f2 d2 e2 fg|a2 ed c/d/e Be|A2 A>B A2 ef|
g3 a b2 ag|f2 d2 e2 fg|a2 ed c/d/e Be|A2 A>B Agfe|
d2 F2 A2 B/c/d|e>^def a2 fe|dBAB d2 d2|d4- d:|
X: 6
T: John O'Shea's
R: march
M: 4/4
L: 1/8
K: Amaj
|:dcB|A2 c2 E2 FA|B>^ABc e2 cB|AFEF A2 A2|A6 Bc|
d3 e f2 ed|c2 A2 B2 cd|e2 BA G/A/B FB|E2 E>F E2 Bc|
d3 e f2 ed|c2 A2 B2 cd|e2 BA G/A/B FB|E2 E>F EdcB|
A2 c2 E2 F/G/A|B>^ABc e2 cB|AFEF A2 A2|A4- A:|
X: 7
T: John O'Shea's
R: march
M: 4/4
L: 1/8
K: Amaj
cB|A2 CD|E2 (3FGA|B3c|e2 cB|AF EF/G/|A2 A2|A4-|A2 Bc|
d2 e2|f2 ed|c2 A2|B2 cd|ed cA|GE F2|E4-|E2 Bc|
d2 e2|f2 ed|c2 A2|B2 cd|ed cA|GE F2|E4-|E BcB|
A2 CD|E2 (3FGA|B3c|e2 cB|AF EF/G/|A2 A2|A4-|A2||
X: 8
T: John O'Shea's
R: march
M: 4/4
L: 1/8
K: Amaj
cB|A2 CD E2 F/G/A|B3 c e2 cB|AF EF/G/ A2 A2|A4- A2 Bc|
d2 e2 f2 ed|c2 A2 B2 cd|ed cA GE F2|E4- E2 Bc|
d2 e2 f2 ed|c2 A2 B2 cd|ed cA GE F2|E4- EBcB|
A2 CD E2 F/G/A|B3 c e2 cB|AF EF/G/ A2 A2|A4- A2||
X: 9
T: John O'Shea's
R: march
M: 4/4
L: 1/8
K: Gmaj
|:c/B/A|G2 D>E D2 D/E/F/G/|A3 B de/d/ c/B/A|GE DE G2 F2|G6 AB|
c3 d ef/e/ dc|B2 G2 A2- AB/c/|dc BG FD EF/E/|D6 A>B|
c2 cd e2 f/e/d/c/|B3 G A2 Bc|d>c BG F>D E>D|D6 d/c/B/A/|
G2 Bc d2 D/E/F/G/|A3 B d2 BA|GE DE G2 F2|G6:|

The Lollipop Man

X: 1
T: The Lollipop Man
R: march
M: 4/4
L: 1/8
K: Gmaj
|:BA|GB D2 D2 EF|G2 GF G3 A|B2 GA BAGA|BEED E2 BA|
GB D2 D2 EF|G2 GF G3 d|edef gedc|BAGF G2:|
|:z2|d4 gf eg|B2 de d3 B|A3 B cBAG|BEED E2 BA|
GB D2 D2 EF|G2 GF G3 d|edef gedc|BAGF G2:|
X: 2
T: The Lollipop Man
R: march
M: 4/4
L: 1/8
K: Gmaj
|:B>A|GB D2 D2 EF|G3 A G3 B|A3 B cBAG|c2 E2 E2 B>A|
GB D2 D2 EF|G3 A GBdg|e>def gedc|B2 G2 G2:|
|:d2|e>de>f g3 B|c>Bc>d e3 G|AGAB cBAG|c2 E2 E2 BA|
GB D2 D2 EF|G3 A GBdg|e>def gedc|B2 G2 G2:|
X: 3
T: The Lollipop Man
R: march
M: 4/4
L: 1/8
K: Amaj
|:c|(AF)EF {F/}A2 (AB)|(A/B/c) T(BA) BFFB|(AF)EF {F/}A2 (Aa)|Tf2 ec eAA:|
a|Tf2 (ec) efac|B/B/B T(BA) BFFB|AFEF TA2 (Aa)|Tf2 (ec) eAAa|
Tf2 (ec) efac|B/B/B T(BA) BFFB|AFEF ABce|faea {d/}cAA||
X: 4
T: The Lollipop Man
R: march
M: 4/4
L: 1/8
K: Gmaj
|:B|GEDE G2 GA|B/A/B AG AEEA|GEDE G2 Gg|e2 dB dGG:|
g|e2 dB degB|A/A/A AG AEEA|GEDE G2 Gg|e2 dB dGGg|
e2 dB degB|A/A/A AG AEEA|GEDE GABd|egdg BGG||
X: 5
T: The Lollipop Man
R: march
M: 4/4
L: 1/8
K: Gmaj
BA|B2D2D2E2|G3A G2B2|A3B cBAG|B2E2E2 BA|
B2D2 D2E2|G3A G2gf|e3d efgd|B2G2G2d2|
edef g2B2|cBcd e2G2|A3B cBAG|B2E2E2 BA|
B2D2 D2E2|G3A G2gf|e3d efgd|B2G2G2||
X: 6
T: The Lollipop Man
R: march
M: 4/4
L: 1/8
K: Gmaj
B>A|G<BD2D2E>F|G3AG2zB|A>GA>B c>BA>G|(3GAB E2E2B>A|
(3GAB D2D2E>F|G3AG2zd|edef (3efg d>c|B<dG2G2:|
|:d2|e>de>f gz2B|c>Bc>d ez2G|A3B c>BA>G|(3GAB E2E2 B>A|
G<BD2D2E>F|G3AG2zd2|edef e<g d<c|B<dG2G2:|
X: 7
T: The Lollipop Man
R: march
M: 4/4
L: 1/8
K: Gmaj
B/A/|{GA} BD DE/F/ G>A GB|A>B c/B/A/G/ {GA} BE EB/A/|
{FA} GD DE/F/ G>A Gg/f/|e>d e/f/g/d/ BGG:|
|:d|(e/d/e/f/) gB (c/B/c/d/) eG|A>B c/B/A/G/ {GA} BE EB/A/|
{GA} BD DE/F/ G>A Gg/f/|e>d e/f/g/d/ BGG:|
|:e/f/|(g/d/).B/.d/ (e/d/).B/.d/ (g/d/).B/.d/ (e/d/).B/.d/|(g/f/).e/.d/ (c/B/).A/.G/ BA Ae/g/|
(g/d/).B/.d/ (e/d/).B/.d/ (g/d/).B/.d/ (e/d/).B/.d/|e>d e/f/g/d/ BGG:|
X: 8
T: The Lollipop Man
R: march
M: 4/4
L: 1/8
K: Gmaj
B>A|G>B D2 D2 D>E|G2 G2 G7/ A/|B>AG>A B2 A>G|B2 E2 E2B>A|
G>B D2 D2 D>E|G2 G2 G7/ d/|e>de>f g2 d>c|B2 G2 G2||
z2|d4 g>fe>g|B2 d2 d2 c>B|A>GA>B c>BA>G|B2 E2 E2 B>A|
G>B D2 D2 D>E|G2 G2 G7/ d/|e>de>f g2 d>c|B2 G2 G2||
X: 9
T: The Lollipop Man
R: march
M: 4/4
L: 1/8
K: Gmaj
B>A|G>B D2 D2 D>E|G2 G2 G7/ A/|B>AG>A B2 A>G|B2 E2 E2B>A|
G>B D2 D2 D>E|G2 G2 G7/ d/|e>de>f g2 d>c|B2 G2 G2||
z2|d4 g>fe>g|B2 d2 d2 c>B|A>GA>B c>BA>G|B2 E2 E2 B>A|
G>B D2 D2 D>E|G2 G2 G7/ d/|e>de>f g2 d>c|B2 G2 G2||
X: 10
T: The Lollipop Man
R: march
M: 4/4
L: 1/8
K: Gmaj
|:BA|G2- GB D2 D/E/F|G2- GA G2- GB|A2 A>B cB AG|c2 E2 E2 c/B/A|
G2 GB D2 EF|G2 GA GB d/e/f/g/|e>^d ef ge dc|B2 G>F G2:|
|:B/c/d|e2- ef g2- gB|c>B B/c/d e2 G2|A>^G AB cB B/A/G|c2 E>^D E2 d/c/B/A/|
G>F GB D2 C/D/E/F/|G2- GA G>B dg|e2- ef g2 e/d/c|B2- BG G2:|

Lord Lovat’s Lament

X: 1
T: Lord Lovat's Lament
R: march
M: 4/4
L: 1/8
K: Amaj
(AB)|c2 (ce) dcBA|(c<e)(e>f) e2 (fg)|a2 (ea) (fe)(cA)|(c<B)(B>c) B2 (AB)|
c2 (ce) (dc)(BA)|c<ee>e fecA|(d>e) (fe/d/) c<edB|(B<A)(A>B) A2 (fg)|
a2 (ea) fecA|(c<e)(e>f) e2 (fg)|a2 (ea) (fe)(cA)|(c<B)(B>c) B2 (fg)|
a2 (ea) (fe)(cA)|c<ee>e fecA|(d>e) (fe/d/) c<edB|(B<A)(A>B) A4||
X: 2
T: Lord Lovat's Lament
R: march
M: 4/4
L: 1/8
K: Amix
(A>B)|c2 (ce) (dc)(BA)|(c<e)(e>f) e2 (f>g)|a2 (ea) (fe)(cA)|(c<B)(B>c) B2 (A>B)|
c2 (ce) (dc)(BA)|(c<e)(e>f) e2(cA)|(d>e) (fe/d/) (c<e)(dB)|A2 (A>B)A2 (f>g)|
a2 (ea) (fe)(cA)|(c<e)(e>f) e2 (f>g)|a2 (ea) (fe)(cA)|(c<B)(B>c) B2 (A>B)|
c2 (ce) (dc)(BA)|(c<e)(e>f)e2(cA)|(d>e) (fe/d/) (c<e)(dB)|A2(A>B) A2||

Miss Hamilton

X: 1
T: Miss Hamilton
R: march
M: 4/4
L: 1/8
K: Gmaj
|:B2 d2 cBAG|dc B/c/d D2 z2|e2 dc Bd gd|cBAG A2 z2|
B/c/d cB AGAF|G/A/BAG ED/E/ G2|dBAG EF/G/ dc|B2 A2 G2 G2:|
|:dedc cBAG|dedc cBAG|Bdgd edcB|cBAG A2 z2|
B/c/d cB AGAF|G/F/G/A/ BG ED/E/ G2|dBAG EF/G/ dc|B2 AG G2 G2:|
X: 2
T: Miss Hamilton
R: march
M: 4/4
L: 1/8
K: Gmaj
B2 d2 cBAG|d>c B/c/d D2 D2|C/D/E DC B,DGD|CB,CG, A,2 A,2|
BdcB AGAF|GBAG EDEG|dBAG EF/G/ DC|B,2 A,2 G,4||
dedc cBAG|dedc cBAG|Bdgd edcB|cBAG A2 A2|
B/c/d cB AGAF|G/F/G/A/ BG ED/E/ G2|dBAG EF/G/ DC|B,2 A,2 G,4||
X: 3
T: Miss Hamilton
R: march
M: 4/4
L: 1/8
K: Gmaj
|:B2 d2 cBAG|dc B/c/d D2 z|e2 dc Bd gd|cBAG A2 z|
B/c/d cB AGAF|G/A/BAG ED/E/ G2|dBAG EF/G/ dc|B2 A2 G2 G2:|
|:dedc cBAG|dedc cBAG|Bdgd edcB|cBAG A2 z|
B/c/d cB AGAF|G/F/G/A/ BG ED/E/ G2|dBAG EF/G/ dc|B2 AG G2 G2:|
|:F2 dc cBAG|E2 FE/F/ G4|gg/f/ gd edcB|cBAG A4|
B/c/d cB AGAF|G/F/G/A/ BG ED/E/ G2|dBAG EF/G/ dc|B2 AG G2 G2:|
|:B2 AG E2 FG|D2 G2 F2 GF|E2 FE/F/ GG/F/ GD|cBAG A4|
B/c/d cB AD FB/A/|Gc Bg/f/ ed/e/ g2|dB AG/F/ EF/G/ dc|B2 AG G2 G2:|
X: 4
T: Miss Hamilton
R: march
M: 4/4
L: 1/8
K: Dmaj
F2F/G/A G>F E>D|A>G F/G/A A,2-A,2|B2A>G F>A d>F|G>F E<D E2-E2|
F/G/A G>F E>D E>C|D/C/D/E/ F>A, B,>C B,<D|A>F G/F/E/D/ B,>A, d/B/A/G/|F>A E>D D2-D2||
A>B A>G F2 E>D|A/>G/A/B/ A>G G>F E<D|F<A d>A B>A G>F|G>F E<D E2-E2|
F/G/A G>F E>D E>C|D/C/D/E/ F>A, B,>C B,<D|A>F G/F/E/D/ B,>A, d/B/A/G/|F>A E>D D2-D2||
X: 5
T: Miss Hamilton
R: march
M: 4/4
L: 1/8
K: Gmaj
B2B/c/d c>B A>G|d>c B/c/d D2-D2|E2D>C B,>D G>B,|C>B, A,<G, A,2-A,2|
B/c/d c>B A>G A>F|G/F/G/A/ B>D E>F E<G|d>B c/B/A/G/ E>D G/E/D/C/|B,>D A,>G, G,2-G,2||
d>e d>c B2 A>G|d/>c/d/e/ d>c c>B A<G|B<d g>d e>d c>B|c>B A<G A2-A2|
B/c/d c>B A>G A>F|G/F/G/A/ B>D E>F E<G|d>B c/B/A/G/ E>D G/E/D/C/|B,>D A,>G, G,2-G,2||

Return From Fingal

X: 1
T: Return From Fingal
R: march
M: 4/4
L: 1/8
K: Edor
|:B2GF EFGA|B2GF E4|AGFA d2A2|B2A2 Bcd2|
B2GF EFGA|B2GF E4|AGFA d2AG|F2E2 E4:|
|:f2e2 e2dc|B2A2 d2A2|B2A2 d2A2|B2A2 Bcde|
f2e2 e2dc|B2A2 d2A2|AGFA d2AG|F2E2 E4:|
X: 2
T: Return From Fingal
R: march
M: 4/4
L: 1/8
K: Emin
|:{ABc}BAGF EFGA|{c}BAGF E4|AGFA d2 A2|{Bc}B2 A2 B^c d2|
{Bc}BAGF EFGA|{Bc}BAGF E4|AGFA d2{ed} A2|F2 E2 {F}E4:|
f2{gf} e2 e2 d^c|B2{^cB} A2 d3 A|B2{^cB} A2 d2 A2|B2{^cB} A2 B^cde|
f2{gf} e2 e2 d^c|B2{^cB} A2 d3 B|AGFA d2{ed} A2|1 F2{GF} E2 E2 g2:|2 F2{GF} E2 E4||
X: 3
T: Return From Fingal
R: march
M: 4/4
L: 1/8
K: Edor
BG/F/ E/F/G/A/|BG/F/ E2|A/G/F/A/ dA|BA B/c/d/e/|
BG/F/ E/F/G/A/|BG/F/ E2|A/G/F/A/ dA|FE E2||
fe ed/c/|BA dA|BA dA|BA B/c/d/e/|
fe ed/c/|BA d2|A/G/F/A/ dG|FE E2||
B2 GF EFGA|B2 GF E4|AGFA d2 A2|B2 A2 Bcde|
B2 GF EFGA|B2 GF E4|AGFA d2 A2|F2 E2 E4||
f2 e2 e2 dc|B2 A2 d2 A2|B2 A2 d2 A2|B2 A2 Bcde|
f2 e2 e2 dc|B2 A2 d4|AGFA d2 G2|F2 E2 E4||
X: 4
T: Return From Fingal
R: march
M: 4/4
L: 1/8
K: Edor
B/A/G/F/ E/F/G/A/|B/A/G/F/ EE|A/G/F/A/ dA|BA B/c/d|
B/A/G/F/ E/F/G/A/|B/A/G/F/ EE|A/G/F/A/ dA|FE E2:|
|:fe ed/c/|BA d>A|BA dA|BA B/c/d/e/|
fe ed/c/|BA d>A|B/A/F/A/ dA|FE E2:|
X: 5
T: Return From Fingal
R: march
M: 4/4
L: 1/8
K: Ador
|:e2 cB ABcd|e2cB A2 d2|dcBd g2d2|e2d2 efg2|
e2 cB ABcd|e2cB A2 d2|dcBd g2dc|B2A2 A4:|
|:b2a2 a2gf|e2 de g2d2|e2d2 g2d2|e2d2 efga|
b2a2 a2gf|e2 de g2d2|dcBd g2dc|B2A2 A4:|
X: 6
T: Return From Fingal
R: march
M: 4/4
L: 1/8
K: Edor
|:B2 GF EFGA|B2GF E2 A2|AGFA d2A2|B2A2 Bcd2|
B2 GF EFGA|B2GF E2 A2|AGFA d2AG|F2E2 E4:|
|:f2e2 e2dc|B2 AB d2A2|B2A2 d2A2|B2A2 Bcde|
f2e2 e2dc|B2 AB d2A2|AGFA d2AG|F2E2 E4:|
X: 7
T: Return From Fingal
R: march
M: 4/4
L: 1/8
K: Fdor
|:c2AG FGAB|c2AG F4|BAGB e2B2|c2B2 cdef|
c2AG FGAB|c2AG F4|BAGB e2Bc|G2F2 F4:|
|:g2f2 f2ed|c2B2 e2B2|c2B2 e2B2|c2B2 cdef|
g2f2 f2ed|c2B2 e2B2|BAGB e2Bc|G2F2 F4:|

Setanta’s Revenge

X: 1
T: Setanta's Revenge
R: march
M: 4/4
L: 1/8
K: Gmin
G2 GF/G/ BG GF/D/|F>G A>G F/D/d- d/c/A/F/|
G>A GF/G/ B/G/ (3B/c/^c/ d2|1 c>A G>F G/B/G- G/B/A//G//F/:|2 c>A G>F G/B/G- G/d/g/a/]|
|:bg gf/d/ bg gf/d/|f>g a>g f/d/c- c/d/g/a/|
[1 bg gf/d/ bg gf/d/|f>g a>f g/b/g- g/d/g/a/:|
[2 g>a gf/d/ gf/d/ fd/B/|c>B G>F G/B/G- G2||

The Star Of The County Down

X: 1
T: The Star Of The County Down
R: march
M: 4/4
L: 1/8
K: Emin
B,D|E2E2 E2DE|G2G2 A2GA|B2AG E2DB,|D6 B,D|
E2E2 E2DE|G2G2 A2GA|B2AG E2E2|E6||
Bc|d2B2 B2AG|A2A2 A2GA|B2AG E2DB,|D6 B,D|
E2E2 E2DE|G2G2 A2GA|B2AG E2E2|E6||
Bc|d2B2 B2AG|A2A2 A2GA|B2AG E2DB,|D6 B,D|
E2E2 E2DE|G2G2 A2GA|B2AG E2E2|E6||
X: 2
T: The Star Of The County Down
R: march
M: 4/4
L: 1/8
K: Amin
E2G2|:A4AB|A3GA2|c4c2|d3cd2|e2d2c2|A2G2E2|G6-|G2c2B2|
A4AB|A3GA2|c4c2|d3cd2|e2d2c2|A4G2|A6-|1 A2E2G2:|2 A4e2||
|:g4e2|e3dc2|d6|d4cd|e3dc2|A2G2E2|G6-|G2c2B2|
A4AB|A3GA2|c4c2|d3cd2|e2d2c2|A4G2|A6-|1 A4e2:|2 A6||
X: 3
T: The Star Of The County Down
R: march
M: 4/4
L: 1/8
K: Amin
M:3/4
E2G2|:A4AB|A3GA2|c4c2|d3cd2|e2d2c2|A2G2E2|G6-|G2c2B2|
A4AB|A3GA2|c4c2|d3cd2|e2d2c2|A4G2|A6-|1 A2E2G2:|2 A4e2||
|:g4e2|e3dc2|d6|d4cd|e3dc2|A2G2E2|G6-|G2c2B2|
A4AB|A3GA2|c4c2|d3cd2|e2d2c2|A4G2|A6-|1 A4e2:|2 A6||
X: 4
T: The Star Of The County Down
R: march
M: 4/4
L: 1/8
K: Amin
EG|"Am"A2A2 A2GA|"F"c2c2 d2cd|"C"e2dc A2GE|"G"G6 EG|
"Am"A2A2 A2GA|"F"c2c2 d2cd|"Am"e2dc A2A2|A6||
ef|"C"g2e2 e2dc|d2d2 d2cd|"G"e2dc A2GE|G6 EG|
"Am"A2A2 A2GA|"F"c2c2 d2cd|"Em"e2dc A2A2|A6||
ef|"Am"g2e2 e2dc|"F"d2d2 d2cd|"C"e2dc A2GE|"G"G6 EG|
"Am"A2A2 A2GA|"F"c2c2 d2cd|"Am"e2dc A2A2|A6||
X: 5
T: The Star Of The County Down
R: march
M: 4/4
L: 1/8
K: Bmin
F2|B2 B2 B2 AF|d2 d2 e2 de|f2 ed BA F2|A6 FA|
B2 B2 B2 (3ABc|d2 d2 e2 de|f2 ed B2 A2|B6 fg|a2 f2 trf2 ed|
e2 e2 fede|f2 ed BA F2|A6 FA|B2 B2 B2 (3ABc|d2 d2 e2 de|
f2 ed B2 BA|B6 fg|a2 ag f2 ed|e2 e2 fede|f2 ed BA F2|
B6 fg|abag f2 ed|e2 e2 fede|f2 ed BA F2|
A6 (3FGA|B2 Bd B2 AB|dcdf e2 de|f2 ed B2 B2|B6||
X: 6
T: The Star Of The County Down
R: march
M: 4/4
L: 1/8
K: Amin
EG|A2A2 A2GA|c2c2 d2cd|e2dc A2GE|G6 EG|
A2A2 A2GA|c2c2 d2cd|e2dc A2A2|A6||
e2|g2e2 e2dc|d2d2 d2cd|
e2dc A2GE|G6 EG|!A2A2 A2GA|c2c2 d2cd|e2dc A2A2|A6||
e2|g2e2 e2dc|d2d2 d2cd|!e2dc A2GE|G6 EG|
A2A2 A2GA|c2c2 d2cd|e2dc A2A2|A6||

Tommy Darky’s Welcome To Raasay

X: 1
T: Tommy Darky's Welcome To Raasay
R: march
M: 4/4
L: 1/8
K: Amix
A3/2B/|c/A3/2e/f3/2 c2- c3/2a/|a3/2g/f/a3/2 c3/2B/A/B3/2|c/A3/2e3/2c/ e/f3/2c3/2a/|a3/2f/e/c3/2 B2 e3/2d/|
c/A3/2e/f3/2 f2- f3/2a/|a3/2g/f/a3/2 c3/2B/A/d3/2|c/A3/2e3/2f/ f/e3/2 a2|e3/2c/c/B3/2 A2 A3/2B/:|
|:c3/2c/ d2- d3/2c/d3/2e/|f/a3/2a3/2g/ f3/2a/a/e3/2|c3/2B/c/A3/2 e3/2c/e/f3/2|c3/2a/a3/2f/ e/c3/2 B2|
B/c3/2c/d3/2- d3/2c/d3/2e/|f/a3/2a3/2g/ f3/2a/a/e3/2|c3/2B/c/A3/2 e3/2f/f/e3/2|a2 e3/2c/c/B3/2 A2:|
X: 2
T: Tommy Darky's Welcome To Raasay
R: march
M: 4/4
L: 1/8
K: Amix
A>B|c<Ae<f c2-c>a|a>gf<a c>BA<B|c<Ae>c e<fc>a|a>fe<c B2 e>d|
c<Ae<f f2- f>a|a>gf<a e>cB<d|c<Ae>f f<e a2|e>cc<B A2 !invisible!|1 A>B:|2 B<c||
|:d2- d3/2c/ d>ef<a|a>gf>a a<ec>B|c<Ae>c e<fc>a|a>f e<c B2 B<c|
[1 d2- d3/2c/ d>ef<a|a>gf>a a<ec>B|c<Ae>f f<e a2|e>cc<B A2 B<c:|
[2 c<Ae<f f2- f>a|a>gf<a e>cB<d|c<Ae>f f<e a2|e>cc<B A2-A2||