Eric M’s tune sets

O’Sullivan’s March, The Coalminer’s, Thugamar Fein An Samhradh Linn, The Bunch Of Keys, Madame Bonaparte, The Kerfunten, Sonny Brogan’s, Tobin’s Favourite, Leslie’s March.

ABC sheet music
T: O'Sullivan's March
M: 6/8
L: 1/8
K: Gmaj
D |: GBA ABd | edB A2 D | GBA ~B2 G |AGG GE D |
GBA ABd | edB A2 D | GBA ~B2 G :|1 AGG G2 D |2 AGG GB d ||
|| e2 g e2 g | ege edB | ded dBd | dgB BAG |
cBc dcd | (3efg B A2 D | GBA ~B2 G | AGG G2 g ||
| ~e3 ~e2d | ege edB | ded dBd | dgB BAG |
cBc dcd | (3efg B A2 D | GBA ~B2 G | AGG G2 D ||
T: The Coalminer's
M: 4/4
L: 1/8
K: Gmaj
DG~G2 GABc|d2BG AGEG|DG~G2 GABd|gedB A2GE|
DG~G2 GABc|d2BG AGEG|DG~G2 GABd|1 gedB G2GE:|2 gedB G2 (3def||
|:~g3e d2ge|d2BG AGEG|~g3e dega|bagb a2ga|
bg~g2 ageg|d2BG AGEG|DG~G2 GABd|1 gedB G2 (3def:|2 gedB G2GE||
T: Thugamar Fein An Samhradh Linn
M: 3/4
L: 1/8
K: Dmix
|:DEG A2A | ABG A2D | GAB c2A | B2G E3 |
cdc B2G | A2D G2E | DcB c2A | G2E D3 :|
T: The Bunch Of Keys
M: 4/4
L: 1/8
K: Gdor
|:DGGF G2 Ac|BG (3GGG dGBG|DFFE EF2 B|A~F3 DFAF|
DGGF G2 Ac|BGGA Bcde|~f3 d cAFA|1 ABAF DGGF:|2 BGAF DGGA||
|:dgg^f fgdg|(3ggg dg agfd|cffe efcf|(3fff ag fAcf|
dgg^f fgdg|(3ggg dg agfd|c~f3 cAFA|1 BGAF DGGA:|2 BGAF DGGF||
T: Madame Bonaparte
M: 4/4
L: 1/8
K: Gmaj
|:dc|B2BA BdBG|c2cB cecA|GBdf gfge|d3e dcBA|
B2BA BdBG|cBcd efge|dBGB cAFA|G2GF G2:|
|:BA|GBdf gfge|d3e dcBA|GBdf gfge|d3e dcBA|
BdGd BdGd|ceAe ceAe|BdGd BdGd|FADA FADA|
BdGd BdGd|cBcd efge|dBGB cAFA|G2GF G2:|
T: The Kerfunten
M: 6/8
L: 1/8
K: Dmaj
|:F3 FED|FGA Bcd|A2 B BAF|~E3 EDE|
|~F3 FED|FGA Bcd|A2 B BAF|1 EFE D2 E:|2 EFE DFA||
|:d3 def|B3 BAB|d3 def|fed efe|
|d3 def|B3 BAB|A2 d dAF|1EFE DFA:|2 EFE D2 E||
T: Sonny Brogan's
M: 6/8
L: 1/8
K: Ador
~A3 cBc|dcd ~e3|~A3 cde|dcA AGE|
AGA cBc|dcd ede|aba ged|BAG A3:|
eaa aba|gef ~g3|eaa aba|ged cAA|
eaa aba|gef ~g3|aba ged|BAG A3:|
T: Tobin's Favourite
M: 6/8
L: 1/8
K: Dmaj
AF|DFA dcd|ecA cde|fdf gfg|ecA GFE|
DFA dcd|ecA cde|(4fgaf gec|edc d:||
d2|dfa agf|(4efge efg|fdf gfg|ecA GFE|
DFA dcd|ecA cde|(4fgaf gec|edc d:||
T: Leslie's March
M: 6/8
L: 1/8
K: Dmaj
|:d3 d3|dcB ABc|dcB AGF|A2F E2D|
e3 ede|fed eag|f2 e d2 A|def e2d :|
|:fed e A2|fed e A2|gfe f B2|gfe f B2|
fed e A2|fed eag|f2 e d2 A|def e2d:|
|:dfa dfa|dfa afd|egb egb|egb bge|
dfa dfa|dfa a2 g|fed d2 A|def e2d :|