Download ABC

Henk Bos’s tunebook: reels

Order by name, newest, oldest.

The Bus Stop

X: 1
T: The Bus Stop
R: reel
M: 4/4
L: 1/8
K: Amin
|:A2e2 d2cB|ABcA BAGB|A2e2 d2cA|(3Bcd e^fg edB|
A2e2 d2cB|ABcA BAGB|(3E^FG AcB AGE|A4 A4:|
|:a2ag edcB|ABcd e2cB|A2ag edcA|de^fd e2cB|
A2ag edcB|ABcd e3d|cBAG E^FGB|A4 A4:|
X: 2
T: The Bus Stop
R: reel
M: 4/4
L: 1/8
K: Ador
A(A|A2) eA dcBc|ABcA BAGB|A2 eA dcBA|(3Bcd ef gfed|
A2 eA dcBc|ABcA BAGD|((4DEFG A)B cBAG|ABAG A2:|
|:ee|a2 ae gedc|Acdf e2 ee|a2 ae gedc|ABcA BAGB|
Aaae gedc|Acdf e2 AA|cBAF EFGB|A2 AG A2:|
X: 3
T: The Bus Stop
R: reel
M: 4/4
L: 1/8
K: Amin
|:"Am"A2 eA dA c2|"Am"ABcA "G"BAGB|"Am"A2eA dAc2|"C"cde^f "G"gedB|
"Am"A2 eA dAc2|"Am"ABcA "G"BAG2|"F"FGAc "G"BAGA|"Am"cABG A4:|
|:"Am"e a2 g edcB|ABcd e4|"Am" e a2 g ed c2|"D"de^fd "E"e4|
"Am" e a2 g edcB|ABcd e2 dc|"G"BAGF EFGB|"Am"cABG A4:|

The Fisherman’s Island

X: 1
T: The Fisherman's Island
R: reel
M: 4/4
L: 1/8
K: Dmaj
D2 FA d2 cA|BAGB AFDF|GEFD EFGA|(3Bcd ed cAAg|
fd ~d2 edcA|BcdB AGFD|EFGA (3Bcd ed|1 cAGE FDCE:|2 cAGE D2 z2||
|:fd ~d2 AF ~F2|DFAd fdef|ge~e2 bece|dfed cAGE|
DF~F2 AddA|B2gf edcB|Adfa gbed|1 cAGE D2 z2:|2 cAGE FDCE||
X: 2
T: The Fisherman's Island
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:D2FA d3A|BAGB AFFF|GEED EFGA|Bded cAA2|
f2df edce|d2cd BAGF|EFGA Bded|cAGE EDD2:|
|:fddA AFFD|DFAd f2ef|geee gfec|dfed cAGE|
DFFA Adcd|Bddg fedB|Adfa gfec|dBAG FDD2:|
X: 3
T: The Fisherman's Island
R: reel
M: 4/4
L: 1/8
K: Dmaj
z|A,DFA d2 cd|BAGB AFDF|(3GFE (3FED CDEF|GBed (3cde Ag|
f2 df e2 ce|dcdc BAGF|EFGB cded|cAGE FDD:|
g|fd d2 AF F2|DFAd fdef|gece bece|geed c/B/A G/F/E|
DF F2 Ad d2|Bg g2 edcB|Adfd g2 ed|cAGE FDD:|
X: 4
T: The Fisherman's Island
R: reel
M: 4/4
L: 1/8
K: Dmaj
D2 FA d2 Ad|BAGB AFDF|GEFD EFGA|(3Bcd ed cAAg|
fd ~d2 edBd|ABde fdAF|EFGA (3Bcd ed|1 cAGE FDDC:|2 cAGE D2 z2||
|:fd ~d2 AF ~F2|DFAd fdef|gecA bgec|defe dBAF|
D2FA defd|Bgg2 edcB|Adfa g2ed|1 cAGE D2 z2:|2 cAGE FDCE||
X: 5
T: The Fisherman's Island
R: reel
M: 4/4
L: 1/8
K: Dmaj
D2 FA d3 A|BAGB AF ~F2|GEED EFGA|(3Bcd ed cAAg|
fd ~d2 edce|d2 cd BAGF|EFGA (3Bcd ed|1 cAGE EDDE:|2 cAGE ED D2||
|:fd ~d2 AF ~F2|DFAd efef|ge~e2 gfec|dfed cAGE|
DF~F2 Ad ~d2|B2gf edcB|Adfa gfed|1 cAGE ED D2:|2 cAGE EDDE||
X: 6
T: The Fisherman's Island
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:A,DFA dfcA|BAGB AFDF|GEFD EFGA|(3Bcd ed cdeg|
fd (3ddd edcA|BcdB AGFD|EFGA (3Bcd ed|1 cAGE FDCE:|2 cAGE D2z2||
|:fd (3ddd AF (3FFF|DFAd fdef|ge (3eee bece|dfed cAGE|
DF (3FFF Ad (3ddd|B2gf edcB|Adfa gbed|1 cAGE D2 z2:|2 cAGE FDCE||
X: 7
T: The Fisherman's Island
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:"D"DEFA d2 dA|"G"BAGB "D"AFDF|"A"GEED EFGA|"G"B/c/d ed "A"cAAg|
"D"fddd "A"ecAc|"D"dddA "G"BAGF|"A"EFGA B/c/d ed|1 cAGE "A7"EDCE:|2 "A7"cAGE "D"EDDg|
|:"D"fddd AFFF|DFAd f2 ef|"A"gece bece|"D"dfed "A"c/B/A GE|
"D"DFFF Adfd|"G"Bggg edcB|"D"Adfa "G"gbed|1 "A"c/B/A GE "D"EDDg:|2 "A"c/B/A GE "D"EDD2||
X: 8
T: The Fisherman's Island
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:D2 FA d2 cA|BAGB AFDF|GEFD EFGA|(3Bcd ed cAAg|
fd d2 edcA|BcdB AGFD|EFGA (3Bcd ed|cAGE FD D2:|
|:fd d2 AF F2|DFAd fdef|ge e2 Be e2|dfed cAGE|
DF F2 AddA|Bg g2 edcB|Adfa gbed|1 cAGE FD D2:|

The Kylebrack Rambler

X: 1
T: The Kylebrack Rambler
R: reel
M: 4/4
L: 1/8
K: Amix
AE E2 AEcE|AE E2 GEDE|AE E2 A3 B|cdec d2 cd|
ea a2 agef|gdeg dBGB|AGED EA A2|1 cedB A3 B:|2 cedB ABcd||
|:e2 de cA A2|a3 g efgf|g2 dg Bgdg|gaba gede|
a2 c'a be e2|^ge e2 Be e2|dB B2 GA (3Bcd|1 gedB ABcd:|2 gedB A2 (3Bcd||
|:eA A2 EA A2|ae e2 agef|g2 fa gedB|Ggfa gedB|
cA A2 EA A2|ae e2 agef|g2 fa gedB|1 GBdB A2 (3Bcd:|2 GBdB A3 B||
X: 2
T: The Kylebrack Rambler
R: reel
M: 4/4
L: 1/8
K: Dmix
DA,~A,2 DA,=FA,|DA,~A,2 CA,G,A,|DA,~A,2 DA,DA|FDAF GEFG|
Adde d^cAB|cGAc GECE|CB,A,G, A,D~D2|1 FAGE D3^C:|2 FAGE DEFG||
|:AFGA FD~D2|dedc AGdB|c2Gc EGce|dced cAGE|
~d2fA ~d2fd|^cA~A2 EA^CA|GE~E2 CDEG|cAGE DEFG:|
|:AD~D2 A,D~D2|dA~A2 dcA_B|BcdB cAGE|CcBd cGEG|
FD~D2 A,D~D2|dA~A2 dcA_B|BcdB cAGE|1 CEGE DEFG:|2 CEGE D3^C||
X: 3
T: The Kylebrack Rambler
R: reel
M: 4/4
L: 1/8
K: Amix
AE E2 AE=cE|AE E2 GEDE|AE E2 A3 B|^cde^c d2 ^cd|
ea a2 agef|gdeg dBGB|AGED EA A2|1 ^cedB A3 B:|2 ^cedB ABcd||
|:e2 de =cA A2|a3 g efgf|g2 dg Bgdg|gabg ageg|
a2 ea be e2|g2 ed Be e2|dB B2 GA (3Bcd|1 gedB ABcd:|2 gedB A2 (3Bcd||
=cA A2 EA A2|ae e2 agef|g2 fa gedB|dgfa gedB|
=cA A2 EA A2|ae e2 agef|g2 fa gedB|1 GBdB A2 (3Bcd:|2 GBdB A3 B||
X: 4
T: The Kylebrack Rambler
R: reel
M: 4/4
L: 1/8
K: Dmix
DA,~A,2 DA,=FA,|DA,~A,2 CA,G,A,|DA,~A,2 DA,DE|FDEF G2FG|
Adde dcAB|cGAc GECD|DCA,G, A,DED|1 FAGE D3E:|2 FAGE DEFG||
AFGA FDED|dedc AGdB|cBcG EGAB|cAdB cAGA|
dAfA dABA|^cABA EAcA|~G2EG CDEG|cAGE DEFG:|
ADED A,DED|dABA dcAB|cdBd cAGE|CcBd cAGA|
FDED A,DED|dABA dcAB|cdBd cAGE|1 CEGE DEFG:|2 CEGE D3E||
X: 5
T: The Kylebrack Rambler
R: reel
M: 4/4
L: 1/8
K: Dmix
D ~A,3 DA,=FA,|D ~A,3 CA,G,A,|D ~A,3 D3E|FGAF G2FG|
Addc dcAB|cGAc GEDC|DCA,G, A,CDE|1 =FAGE DE=FE:|2 =FAGE DE^FG||
A2GE FDFA|~d3c AGAB|c2Gc EcGc|cded cAGA|
defe dAAB|1 ^cAAG E (3AAA|G~E3 CDEG|cAGE DEFG:|2 ^cAAG ~E3(G|~G2)ED CDEG|cAGE DEFG:|
AD (3DDD A,DFA|d (3AAA dcAB|c2Bd cAGE|CcBd cAGE|
F (3DDD A,DFA|d (3AAA dcAB|c2Bd cAGE|1 CDEC DEFG:|2 CDEC D2=FE||
X: 6
T: The Kylebrack Rambler
R: reel
M: 4/4
L: 1/8
K: Dmix
DA,~A,2 DA,=FA,|DA,~A,2 CA,G,A,|DA,~A,2 D3E|FGAF G2FG|
Adde dcAB|cGAc GECE|DCA,G, A,D~D2|1 FAGE DE=FE:|2 FAGE DEFG||
AFGE FD~D2|d3c AGAB|c2Gc EcGc|cded cAGA|
d2fd dA ~A2|^cA~A2 EA~A2|GE~E2 CDEG|cAGE DEFG|
AD~D2 A,D~D2|dA~A2 dcAB|c2Bd cAGE|CcBd cAGE|
FD~D2 A,D~D2|dA~A2 dcAB|c2Bd cAGE|CEGE DE=FE||
X: 7
T: The Kylebrack Rambler
R: reel
M: 4/4
L: 1/8
K: Dmix
DA,~A,2 DA,=FA,|DA,~A,2 CA,G,A,|DA,~A,2 D3E|FGAF G2FG|
Adde dcAB|cGAc GECE|DCA,G, A,D~D2|1 FAGE D2DE:|2 FAGE D2FG:|
AFGA FD~D2|d3c AGAB|c2Gc EcGc|cded cAGA|
d2fd dA ~A2|^cA~A2 EA~A2|GE~E2 CDEG|cAGE D2FG:|
AD~D2 A,D~D2|dA~A2 dcAB|c2Bd cAGE|CcBd cAGE|
FD~D2 A,D~D2|dA~A2 dcAB|c2Bd cAGE|CEGE D2DE:|
X: 8
T: The Kylebrack Rambler
R: reel
M: 4/4
L: 1/8
K: Amix
|:AE ~E2 AEcE|AE ~E2 GEDE|AE ~E2 ABcA|cdec d2 cd|
eaa_a =agef|gdeg dBGB|AGED EA ~A2|1 cedB A2 AG:|2 cedB A2cd||
|:ecde cA ~A2|a2 ag egaf|g2 dg egdg|~g2 bg ageg|
a2 ea c'aea|ge ~e2 defg|edBA GABd|eAdB A2cd:|
|:eA ~A2 EAce|ae ~e2 agef|g2 fa gede|~g2 bg aged|
cA ~A2 EAce|ae ~e2 agef|g2 fa gedB|1 GABG A2 cd:|2 GABG A4||
X: 9
T: The Kylebrack Rambler
R: reel
M: 4/4
L: 1/8
K: Dmix
|:DA, (3A,^G,A, DA,=FA,|DA, (3A,^G,A, CA,=G,A,|DA, (3A,^G,A, DA,DA|FDAF GEFG|
Adde d^cAB|cGAc GECE|CB,A,G, A,D (3D^CD|1 FAGE D3^C:|2 FAGE DEFG||
|:AFGA FD (3D^CD|dedc AGdB|{e}c2 (3GBc EGce|dced cAGE|
(3d^cd fA (3d^cd fd|^cA (3A^GA EA^CA|GE (3E^DE C=DEG|cAGE DEFG:|
|:AD (3D^CD A,D (3D^CD|dA (3A^GA dcA_B|BcdB cAGE|CcBd cGEG|
FD (3D^CD A,D (3D^CD|dA (3A^GA dcA_B|BcdB cAGE|1 CEGE DEFG:|2 CEGE D3^C||
X: 10
T: The Kylebrack Rambler
R: reel
M: 4/4
L: 1/8
K: Dmix
|:dA~A2 dA=fA|dA~A2 cAGA|dA~A2 dAda|fdaf gefg|
adde d^cAB|cGAc G~E3|cBAG Ad~d2|1 fage d3^c:|2 fage defg||
|:afga fd~d2|dedc AGdB|c2Gc EGce|dced cAGE|
~d2fA ~d2fd|^cA~A2 EA^cA|GE~E2 cDEG|1 cAGE defg:|2 cAGE DEFG||
|:AD~D2 AD~D2|dA~A2 dcAB|BcdB cAGE|ccBd cGEG|
FD~D2 AD~D2|dA~A2 dcAB|BcdB cAGE|1 cEGE DEFG:|2 cEGE D3^c||

Lizzy In The Lowground

X: 1
T: Lizzy In The Lowground
R: reel
M: 4/4
L: 1/8
K: Gdor
|:B3G FGBc|dfgd fdcB|d3g gagf|gdfc dBcd|
B3G FGBc|dfgd fdcd|gdfc dBcd|1 BGFB GBBA:|2 BGFB GBB2||
|:B,3C B,CDF|G2dG cBGF|G2dG cBGF|G2dG FDCD|
B,3C B,CDF|G2dG cBGF|G2dG cBGB|BGFB GBB2:|
X: 2
T: Lizzy In The Lowground
R: reel
M: 4/4
L: 1/8
K: Gdor
|:d3B ABde|fabf abed|bfaefdaf|1 dBAd Bddc:|2 dBAd BAFE||
|:D3E DEFA|B2fB edBA|B2fB edBA|B2fB AFEF|
D3E DEFA|B2fB edBA|B2fB edBd|1 dBAd BAFE:|2 dBAd Bdde||
X: 3
T: Lizzy In The Lowground
R: reel
M: 4/4
L: 1/8
K: Gdor
|:d3B ABde|fabf abed|f3b b2ba|bfde fdef|
d3B ABde|fabf abed|bfae fdaf|1 dBAd Bddc:|2 dBAd BAFE||
|:D3E DEFA|B2fB edBA|B2fB edBA|B2fB AFEF|
D3E DEFA|B2fB edBA|B2fB edBd|1 dBAd BAFE:|2 dBAd Bdde||
X: 4
T: Lizzy In The Lowground
R: reel
M: 4/4
L: 1/8
K: Edor
|:G2EG DEGA|BdeB dBAG|B3e efed|eBdA BGAB|
G3E DEGA|BdeB dBAB|eBdA BGAB|1 GEDG EGGF:|2 GEDG EGG2||
|:G,3A, G,A,B,D|E2BE AGED|E2BE AGED|E2GE DB,A,B,|
G,3A, G,A,B,D|E2BE AGED|E2BE AGEA|GEDG EGG2:|
X: 5
T: Lizzy In The Lowground
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:G3E DEGA|ABde dBAd|Beed efed|eBdA BGAE|
G3E DEGA|ABde dABd|eBdA BGAB|GEDG EGGF:|
|:G3F GABd|e2bg aged|e2bg aged|e2ge dBAB|
G3F GABd|e2bg aged|e2bg agea|1 gded eggg:|2 gded egdB||
X: 6
T: Lizzy In The Lowground
R: reel
M: 4/4
L: 1/8
K: Amaj
|:A3F EFAB|cefc ecBA|c3f fgfe|fceB cABc|
A3F EFAB|cefc ecBc|fceB cABc|1 AFEA FAAG:|2 AFEA FAA2||
|:A,3B, A,B,CE|F2cF BAFE|F2cF BAFE|F2cF ECB,C|
A,3B, A,B,CE|F2cF BAFE|F2cF BAFA|AFEA FAA2||

Lost In The Loop

X: 1
T: Lost In The Loop
R: reel
M: 4/4
L: 1/8
K: Cmaj
CDEF DA,A,F|EFGA FDD^F|GABc dcBc|dDcD BAGA,|
CDEF DA,A,F|EFGA FDD^F|GABc d2GF|1 DA,CD FD D/D/D:|2 DA,CD FDDA||
dDDc BGG2|ADDF ECCD|dDcD BAGA,|CDEF DA,A,A|
dDDc BGG2|ADDF ECCE|GABc d2GF|DA,CD FDDA||
d2d2 gadc|d2dc AGAc|dGGd GGdD|CDEF DA,A,A|
d2d2 gadc|d2dc AGAc|dDcD GABc|dDcD A,D D/D/D:|
X: 2
T: Lost In The Loop
R: reel
M: 4/4
L: 1/8
K: Cmaj
"C"CDEF "Dm"DA,A,F|"Em"EFGA "F"FDD^F|"G"GABc dcBc|"G"dDcD BAGA,|
"C"CDEF "Dm"DA,A,F|"Em"EFGA "F"FDD^F|"G"GABc d2GF|"G"1 DA,CD "Am"FD D/D/D:|"G"2 DA,CD "Am"FDDA||
"Dm"dDDc "G"BGG2|"Dm"ADDF "C"ECCD|"Dm"dDcD "G"BAGA,|"G"CDEF "Am"DA,A,A|
"Dm"dDDc "G"BGG2|"Dm"ADDF "C"ECCE|"G"GABc d2GF|"G"DA,CD FDDA:|
"Dm"d2d2 gadc|"Dm"d2dc AGAc|"G"dGGd GGdD|"G"CDEF DA,A,A|
"Dm"d2d2 gadc|"Dm"d2dc AGAc|"G"decA GABc|"Am"dDcD "G"A,G G/G/G:|
X: 3
T: Lost In The Loop
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:GABc AEE2|Bcde cAA2|defg agfg|eAgA edcB|
GABc AEE2|Bcde cAA^c|defg a2dc|1 AEGA cA A/A/A:|2 AEGA cAAe||
|:eAA2 fdd2|eAAc BGGA|eAA2 edcB|GABc AEE2|
eAA2 fdd2|eAAc BGG2|defg a2dc|AEGA cAAG||
|:A2A2 DEE2|A3G EDEG|ADDA DDAD|GABc AEE2|
A2A2 DEE2|A3G EDEG|eAA2 defg|eAA2 AEGA:|

The Plough And The Stars

X: 1
T: The Plough And The Stars
R: reel
M: 4/4
L: 1/8
K: Gmaj
GEDE GABd|gabg aged|B3d e2de|gedB AcBA|
GEDE GABd|gabg aged|Bd~d2 eBdB|1 AGAB G2BA:|2 AGAB G2 (3def||
|:g3b a2ba|gabg aged|Bd~d2 ed~d2|gedB AcBA|
GEDE GABd|gabg aged|Bd~d2 eBdB|1 AGAB G2 (3def:|2 AGAB G2 BA||
X: 2
T: The Plough And The Stars
R: reel
M: 4/4
L: 1/8
K: Fmaj
|:FDCD FGAc|fg (3agf gfdc|Ac (3ccc dAcA|fdcA ~B2 AG|
FDCD FGAc|fg (3agf gfdc|Ac (3ccc dAcA|1 GFGA FBAG:|2 GFGA FGAc||
|:~f3 a ~g3 a|fgaf gfdc|Ac ~c2 d2 cd|fdcA (3BcB AG|
FDCD FGAc|fgaf gfdc|Ac ~c2 dAcA|GFGA FGAc:|
X: 3
T: The Plough And The Stars
R: reel
M: 4/4
L: 1/8
K: Gmaj
GEDE GABd|gabg aged|Bd~d2 ed~d2|gedB AcBA|
GEDE GABd|g2 bg a2 ge|Bd~d2 gedB|AcBA G3 A:|
|:g3b a2ba|gabg aged|Bd~d2 ed~d2|gedB AcBA|
GEDE GABd|g2 bg a2 ge|Bd~d2 gedB|AcBA G3 A:|

Ramnee Ceilidh

X: 1
T: Ramnee Ceilidh
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:dBBd ~A2BA|feef e2de|faaf e2fe|d2ed BdBA|
dBBd ~A2BA|feef e2de|faaf e2fe|1 dBAB d2d2:|2 dBAB d3e||
|:~f3A Bde2|ed~d2 edBd|~f3A Bde2|edfe d3e|
~f3A Bde2|ed~d2 edBd|faaf e2fe|1 dBAB d2de:|2 dBAB d4||
X: 2
T: Ramnee Ceilidh
R: reel
M: 4/4
L: 1/8
K: Dmaj
d|dBBd A2BA|feef e2de|faaf e2fe|d2de dBA2|
dBBd A2BA|feef e2de|faaf eafe|dBAB d3:|:e|
f2fA Bde2-|edBd edBd|effA Bde2-|edfe d3e|
f2fA Bde2-|edBd edBd|faaf eafe|dBAB d3:|
X: 3
T: Ramnee Ceilidh
R: reel
M: 4/4
L: 1/8
K: Gmaj
GEEG D2GA|BGcB ABGA|B2dB A2BA|G3A GEED|
GEEG D2GA|BGcB ABGA|B2dB A2BA|1 GEDE G3A:|2 GEDE GDEG||
B3D EGA2|ADEG AGEG|B3D EGA2|ABcB AGEG|
B3D EGA2|ADEG AGEG|B2dB A2BA|1 GEDE GDEG:|2 GEDE G3A||
X: 4
T: Ramnee Ceilidh
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:dBBd A2 de|f2 af e2de|faaf e2fe|d3e dBAB|
dBBd A2 de|f2 af e2de|faaf e2fe|1 dBAB d2d2:|2 dBAB d3e||
|:f3A Bd e2|ed d2 edBd|f3A Bde2|edfe d3e|
f3A Bd e2|ed d2 edBd|faaf e2fe|1 dBAB d2de:|2 dBAB d4||
X: 5
T: Ramnee Ceilidh
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:dBBd A2 de|fdgf e2de|faaf e2fe|d3e dBAB|
dBBd A2 de|fdgf e2de|faaf e2fe|1 dBAB d2d2:|2 dBAB d3e||
|:f3A Bd e2|ed d2 edBd|f3A Bde2|e3f gfed|
f3A Bd e2|ed d2 edBd|faaf e2fe|1 dBAB d2de:|2 dBAB d4||
X: 6
T: Ramnee Ceilidh
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:dBBd A2 de|fdgf e2de|faaf e2fe|d3e dBAB|
dBBd A2 de|fdgf e2de|faaf e2fe|1 dBAB d2d2:|2 dBAB d3e||
|:f3A Bd e2|ed d2 edBd|f3A Bde2|edfe d3e|
f3A Bd e2|ed d2 edBd|faaf e2fe|1 dBAB d2de:|2 dBAB d4||
X: 7
T: Ramnee Ceilidh
R: reel
M: 4/4
L: 1/8
K: Gmaj
GEEG D2GA|BGcB ABGA|B2dB A2BA|G3A GEED|
GEEG D2GA|BGcB ABGA|B2dB A2BA|1 GEDE G3A:|2 GEDE GDEG||
B3D EGA2|ADEG AGEG|B3D EGA2|ABcB AGEG|
B3D EGA2|ADEG AGEG|B2dB A2BA|1 GEDE GDEG:|2 GEDE G3A||
K:Amaj
AFFA E2AB|cAdc BcAB|c2ec B2cB|A3B AFFE|
AFFA E2AB|cAdc BcAB|c2ec B2cB|1 AFEF A3B:|2 AFEF AEFA||
c3E FAB2|BEFA BAFA|c3E FAB2|Bcdc BAFA|
c3E FAB2|BEFA BAFA|c2ec B2cB|1 AFEF AEFA:|2 AFEF A3B||"LAST"AGEG .A2z2||
X: 8
T: Ramnee Ceilidh
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:dBBd A2BA|feef ~e2de|faaf ~e2fe|d2ed BdBA|
dBBd A2BA|feef e{g}ede|faaf e{g}efe|1 dBAB d2d2:|2 dBAB d3e||
|:~f3A Bde2|eABd edBd|~f3A Bde2|efgf edBd|
~f3A Bde2|eABd edBd|faaf e2fe|1 dBAB d2de:|2 dBAB d4||

The Reunion

X: 1
T: The Reunion
R: reel
M: 4/4
L: 1/8
K: Amin
|:EAAA cBcd|eaag agef|(3gfe dB edBA|dBAG AGED|
EAA2 cBcd|eaag agef|g3e dBB2|1 cBAG A3G:|2 cBAG A3z||
|:aAA gAA aA|A gAA agef|gedB Aged|BAge dBAG|
EAAA cBcd|eaag agef|g3e dBB2|1 cBAG Az3:|2 cBAG A3G||

Sevens

X: 1
T: Sevens
R: reel
M: 4/4
L: 1/8
K: Edor
|:E2FE GEAE|B2AG FGB,D|C2DA, EA,FA,|G2FE DEB,D|
[1 E2FE GEAE|B2AG FGB,D|C2DA, EA,FA,|G2FE DEB,D:|
[2 EB,B,F B,B,GB,|AB,B,G B,B,FD|CA,A,D A,A,EA,|GA,A,F A,A,ED||
EBeB EBeB|EBeB cAec|DAdA DAdA|DAdA GFED|
EBeB EBeB|EBeB cAec|Adfd AdfA|Bfdf BfdD||

The Tinker’s Daughter

X: 1
T: The Tinker's Daughter
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:A2 FA DAFA|defd efdB|A2 FA DAFA|B2 dB BAFB|
A2 FA DAFA|defd efde|faaf bfaf|1 (3efe de fedB:|2 (3efe de fdde||
faaf bfaf|defd (3efe de|f2 df efdB|ABdf edBd|
faaf bfaf||defd (3efe de|f2 df efdB|AFEF D2 de|
faaf bfaf|defd (3efe de|f2 df efdB|ABdf edBd|
A2 FA DAFA|defd efde|faaf bfaf|(3efe de fedB||
X: 2
T: The Tinker's Daughter
R: reel
M: 4/4
L: 1/8
K: Dmaj
A2 FA DAFA|defd efdB|A2 FA DAFA|B2 dB BAFB|
A2 FA DAFA|defd efde|faaf bfaf|1 (3efe de fedB:|2 (3efe de fdde||
faaf bfaf|defd (3efe de|f2 df efde|f2 df edBd|
faaf bfaf|defd (3efe de|f2 df efdB|1 AFEF D2 de|2 AFEF DAdB||
X: 3
T: The Tinker's Daughter
R: reel
M: 4/4
L: 1/8
K: Dmaj
dB|:A2FA DFAd|f2fd efdc|A2FA DAFA|B2dB BAFB|
A2FA DFAd|f2fd efd2|faaa b2af|e2de fdd2:|
|:faaa baaf|dfaf e2de|f2df efdf|f2df edBd|
faaa baaf|dfaf e2de|f2df efdB|AFEG FDD2:|
X: 4
T: The Tinker's Daughter
R: reel
M: 4/4
L: 1/8
K: Dmaj
|:A2 FA DAFA|f3d efdB|A2 FA DAFA|B3d BAFB|
A2 FA DAFA|f3d efde|faaf bfaf|1 e2 de fedB:|2 e2 de fdde||
faaf bfaf|defd e2 de|f2 df efdB|ABdf ed (3Bcd|
faaf bfaf|defd e2 de|f2 df efdB|AFEF D2 de|
fa a2 bfaf|defd e2 de|f2 df efdB|ABdf ed (3Bcd|
A2 FA DAFA|f3d efde|fa a2 bfaf|e2 de fd d2||

Welcome To Ghent

X: 1
T: Welcome To Ghent
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:B2BA GBdg|e/f/g dB ABGA|B2BA GBdg|1 e/f/g fa gedc:|2 e/f/g fa g2z2||
gBB aBB gB|B gBB gfed|B/c/d ef g2ga|gedB A2GA|
gBB aBB gc|c gcc gfed|B/c/d ef g2ga|gedB A2GA||