Download ABC

Tagt The Spellcaster’s tunebook

Order by name, newest, oldest or tune type.

An Dro barndance

X: 1
T: An Dro
R: barndance
M: 4/4
L: 1/8
K: Dmaj
fedc d2Ad|BAGB A3G|~F3G A2BA|GABG ~E3g|
fedc d2Ad|BAGB A3G|~F3G A2BA|GFEF D4:|
DEFG ADDA|BDDB ADDA|BDDB ADDA|GABG ~E3F|
DEFG ADDA|BDDB ~A3G|~F3G A2BA|GFEF D4:|
X: 2
T: An Dro
R: barndance
M: 4/4
L: 1/8
K: Dmaj
|:fedc d2Ad|BAGB A3G|F3G A2BA|GABG E3g|
fedc d2Ad|BAGB A3G|F3G A2BG|FGEF D4:|
|:DEFG ADDA|BDDB ADDA|BDDB ADDA|GABG E3F|
DEFG ADDA|BDDB A3G|F3G A2BG|FGEF D4:|

An Dro barndance

X: 1
T: An Dro
R: barndance
M: 4/4
L: 1/8
K: Amin
|:E|AB cA B2 e2|de dc B2 cB|AB cA B2 ee|de dc B3:|
|:c|e2 ed c2 e2|dc BA E3 E|AB cA d2 dc|B2 c2 A3:|
X: 2
T: An Dro
R: barndance
M: 4/4
L: 1/8
K: Amin
|:AB cA B2 e2|d2 dc B2 cB|AB c/B/A B2 e2|d2 dc B4:|
|:ef ed c2 e2|dc BA E4|A2 cA d2 dc|B2 c2 A4:|

An Dro reel

X: 1
T: An Dro
R: reel
M: 4/4
L: 1/8
K: Emin
B3c B2A2|G2F2 E2FG|A2A2 F2D2|EFGA B4|
B3c B2A2|G2F2 E2FG|A2A2 F2D2|EFGF E4||
B2d2 E4|B2d2 F4|A2A2 F2D2|EFGA B4|
B2d2 E4|B2d2 F4|A2A2 F2D2|EFGF E4||
E2DE F2A2|GFED E2G2|E2DE F2A2|GFED E4|
E2DE F2A2|GFED EFGF|E2DE F2A2|GFED E4||
B2AB c2A2|A2GA B2G2|E2DE F2A2|GFED EFGA|
B2AB c2A2|A2GA B2G2|E2DE F2A2|GFED E4||
X: 2
T: An Dro
R: reel
M: 4/4
L: 1/8
K: Dmin
L: 1/16
A2AB A2AG F2E2 D4|G2G2 EDC2 DEFG ABA2|A2AB A2AG F2E2 D4|G2G2 EDC2 DEFE D4:|
A2c2 D4 A2c2 E4|G2G2 EDC2 DEFG ABA2|A2c2 D4 A2c2 E4|G2G2 EDC2 DEFE D4:|
X: 3
T: An Dro
R: reel
M: 4/4
L: 1/8
K: Bmin
|:f3g f3e|d2c2 B3B/c/|e2e2 c2BA|Bcde f2B2|
f3g f3e|d2c2 B3B/c/|e2e2 c2BA|1 Bcdc B4:|2 Bcdc B3e||
|:f2b2 B3e|f2b2 c3B/c/|e2e2 c2BA|Bcde f3e|
f2b2 B3e|f2b2 c3B/c/|e2e2 c2BA|1 Bcdc B3e:|2 Bcdc B4||
|:B2AB c2e2|dcBA Bcdc|B2AB c2e2|dcBA B4:|
|:f2ef g2e2|e2de f2d2|B2AB c2e2|dcBA Bcde|
f2ef g2e2|e2de f2d2|B2AB c2e2|dcBA B4:|

An Dro Marc D’ Ailleurs barndance

X: 1
T: An Dro Marc D' Ailleurs
R: barndance
M: 4/4
L: 1/8
K: Amin
|:AB cd e2 e2|de dc B2 Bc|d2 B2 c2 A2|A2 GA B2 B2|
AB cd e2 e2|de dc B2 Bc|d2 B2 c2 A2|A2 G2 A4:|
|:E2 AB c2 c2|Bc dc B4|c2 A2 A2 Bc|d2 cd e2 e2|
E2 AB c2 c2|B2 dc B4|c2 A2 A2 Bc|B2 G2 A4:|
X: 2
T: An Dro Marc D' Ailleurs
R: barndance
M: 4/4
L: 1/8
K: Amin
|:E|AB cd e2 e2|de dc B3 c|d2 B2 c2 A2|1 A/B/A ^GA B3:|2 A2 ^G2 A3||
|:B|E/F/E AB c2 c2|B/c/B dc B3 c|d2 A2 A2 ^GA|1 d2 cd e3|2 B2 ^G2 A3||

Brian Boru’s March jig

X: 1
T: Brian Boru's March
R: jig
M: 6/8
L: 1/8
K: Amin
ed|:c3/2B/A Aed|cBA Adc|B3/2A/G Gdc|BAG Ged|
c3/2B/A Aed|cBA A3|Acd e2 d|1 cBA Aed:|2 cBA A2 G||
|:Acd e2 d|e2 d e3/2c/A|GAB d2 B|d2 B d3/2B/G|Acd e2 d|
e2 d e3/2c/A|A3/2c/d e2 d|1 c3/2B/A A2 G:|2 c3/2B/A A2 B||
|:c3/2B/A a2 a|c3/2B/A a2 a|B3/2A/G g2 g|B3/2A/G g2 B|
c3/2B/A a2 a|c3/2B/A a2 b|c'ba gfe|dcB A2 B:|
|:cde g2 e|g2 e g3/2e/c|GAB d2 B|d2 B d3/2B/G|
cde g2 e|g2 e g3/2e/c|Acd e2 d|1 c3/2B/A A2 B:|2 c3/2B/A A2||
X: 2
T: Brian Boru's March
R: jig
M: 6/8
L: 1/8
K: Edor
B|:G>FE E2B|G>FE E2A|F>ED D2A|F>ED D2B|
G>FE E2B|G>FE E3|EGA B2A|1 G<EE E2:|2 G<EE E3||
|:DGA B2A|B2A BAG|DFG A2F|A2F AFD|
EGA B2A|B2A BAG|EGA B2A|1 G<EE E3:|2 G<EE E3||
X: 3
T: Brian Boru's March
R: jig
M: 6/8
L: 1/8
K: Amin
|:e|cBA Aed|cBA A2 d|BAG Gdc|BAG G2 e|
cBA Aed|cBA A2B|cde e2d|cAA A2:|
|:B|cde efe|efe edc|Bcd ded|ded dcB|
cde efe|efe edc|e3 e2d|cAA A2:|
X: 4
T: Brian Boru's March
R: jig
M: 6/8
L: 1/8
K: Amin
ed|:c3/2B/A Aed|c3/2B/A Adc|B3/2A/G Gdc|B3/2A/G Ged|
c3/2B/A Aed|c3/2B/A A3|A3/2c/d e2 d|1 c3/2B/A Aed:|2 c3/2B/A A2 G||
|:A3/2c/d e2 d|e2 d e3/2c/A|G3/2A/B d2 B|d2 B d3/2B/G|A3/2c/d e2 d|
e2 d e3/2c/A|A3/2c/d e2 d|1 c3/2B/A A2 G:|2 c3/2B/A A2 B||
|:c3/2B/A a2 a|c3/2B/A a2 a|B3/2A/G g2 g|B3/2A/G g2 g|
c3/2B/A a2 a|c3/2B/A a2 a|A3/2c/d e2 d|c3/2B/A A2B:|
|:c3/2d/e g2 e|g2 e g3/2e/c|G3/2A/B d2 B|d2 B d3/2B/G|
c3/2d/e g2 e|g2 e g3/2e/c|A3/2c/d e2 d|1 c3/2B/A A2 B:|2 c3/2B/A A2||
X: 5
T: Brian Boru's March
R: jig
M: 6/8
L: 1/8
K: Edor
B|"Em"G FE E2 B|G FE E2 A|"D"F ED D2A|F ED D2 B|
"Em"G FE E2 B|G FE E3|EGA BAG|FEDD2 B:|
"G"D GA BAG|BAG Bcd|"D"D FG AGF|AGF AGF|
"Em"E GA BAG|BAG Bcd|EGA BAG|FEDD2 B:|
"Em"GFE B2B|GFE B2B|"D"FED A2A|FED A2A|
"Em"GFE B2B|GFE B2B|EGA BAG|FEDD2 B:|
X: 6
T: Brian Boru's March
R: jig
M: 6/8
L: 1/8
K: Amin
B|:GFE E2B|GFE E2A|FED D2A|FED D2B|
GFE E2B|GFE E2A|EGA B2A|GFE E3:|
|:EGA B2A|B2A BAG|DFG A2F|A2F AFD|
EGA B2A|B2A BAG|EGA B2A|GFE E3:|
X: 7
T: Brian Boru's March
R: jig
M: 6/8
L: 1/8
K: Emin
BA|:GFE EBA|GFE EAG|FED DAG|FED DBA|
GFE EBA|GFE E3|EGA ~B2A|1 GFE EBA:|2 GFE E3||
|:EGA ~B2A|~B2A BAF|DEF AFD|AFD AFD|
EGA ~B2A|~B2A ~B2A|GFE ~B2A|GFE E3:|
|:GFE e2e|GFE e2e|FED d2d|FED d2d|
GFE e2e|GFE e3|EGA ~B2A|1 GFE E3:|2 GFE EBA||
X: 8
T: Brian Boru's March
R: jig
M: 6/8
L: 1/8
K: Amin
|:e3/2d3/2"Am"c-|c2BA2A-|A2e3/2d3/2"F"c-|c2BA2A-|A2dc3|"G"B2AG2G-|G2d3/2c3/2"Em"B-|B2A G2G-|G2e d3|
"Am"c2BA2A-|A2e3/2d3/2"F"c-|c2BA2A-|A4 z E|"D"A2c d2"E"e-|e3 d3|"Am"c2B A2A-|A6|
z3 e2"Am"a-|a2g e2a-|a3- a2"F"a-|a2g e2g-|g3- g2"G"g-|g2a b2g-|g2e "Em"dd2-|d2e g2a-|a3- a2"Am"a-|
a2g e2a-|a3- a2"F"a-|a2g e2"D"d-|d2e g2"Em"e-|e3 d3|"Am"c2B A2A-|A6-|A2:|
X: 9
T: Brian Boru's March
R: jig
M: 6/8
L: 1/8
K: Ador
e|:c>BA A2e|c>BA A2d|B>AG G2d|B>AG G2e|
c>BA A2e|c>BA A2E|AB/c/d e2d|1 c>BA A2e:|2 c>BA A>BA/F/||
|:G>cd e2d|e2d e2d|G>Bc d2B|d2e d>BG|
A>cd e2d|e2d e2d|c>BA e2d|c>BA A2B:|
|:c>BA a2A|c>BA a2A|B>AG g2G|B>AG g2B|
c>BA a2A|c>BA a3|AB/c/d e2d|1 c>BA A2B:|2 c>BA A2||

Eleanor Plunkett waltz

X: 1
T: Eleanor Plunkett
R: waltz
M: 3/4
L: 1/8
K: Gmaj
GA|B2B2AG|G2G2ag|e2e2 ed|B2B2AG|E2A2 AB|
A4 ga|b2 aged|e4 ef|g2g2b2|a2 bagf|g2 agfe|d2B2d2|e2g2G2|B2B2AG|E2A2AB|A4|
X: 2
T: Eleanor Plunkett
R: waltz
M: 3/4
L: 1/8
K: Gmaj
GA|"G"B2 B2 AG|"G/B"G2 G2 ag|"C"e2 e2 ed|"Em"B4 AG|"Am7"E2 A2 AB|"D"A4 ga|
"Em"b2 ag ed|"C"e4 ef|"Em"g2 g2 b2|"D"a2 ba gf|"Em"g2 ag fe|
"G"d2 B3 d|"C"e2 g2 G2|"G"B4 AG|"Am7"E2 A2 AB|"D"A4||
X: 3
T: Eleanor Plunkett
R: waltz
M: 3/4
L: 1/8
K: Amin
V:1
GA|"G"B2 B2 AG|"G/B"G2 G2 ag|"C"e2 e2 ed|"Em"B4 AG|
V:2
GA|G2 G2 ED|B4 GA|c2 c2 ed|d4 cB|
V:1
"Am7"E2 A2 AB|"D"A4 ga|"Em" b2 ag ed|"C"e4 ef||
V:2
A2 c3e|d4 e2|g2 d2 B2|c4 c2||
V:1
"Em"g2 g2 b2|"D"a2 ba gf|"Em"g2 ag fe|"G"d2 B3d|
V:2
B2 e2 B2|d2 ed cB|c2 dc BA|B6|
V:1
"C"e2 g2 G2|"G"B4 AG|"Am7"E2 A2 AB|"D"A4||
V:2
c2 G2 e2|d4 cB|A2 c3e|d4||
X: 4
T: Eleanor Plunkett
R: waltz
M: 3/4
L: 1/8
K: Gmaj
GA|B2 B2 AG|G2 G2 ag|e2 e2 ed|B2 B2 AG|
E2 A2 AB|A4 ga|b2 ag ed|e4 ef|
g2 g2 b2|a2 ba gf|g2 ag fe|d2 B2 d2|
e2 g2 G2|B2 B2 AG|E2 A2 AB|A4||

The Harvest Home hornpipe

X: 1
T: The Harvest Home
R: hornpipe
M: 4/4
L: 1/8
K: Dmaj
|:AF|DAFA DAFA|defe dcBA|eAfA gAfA|(3efe (3dcB AGFE|
DAFA DAFA|defe dcBA|eAfA gfec|d2 f2 d2:|
|:cd|eAAA fAAA|gAfA eAAA|eAfA gAfA|(3efe (3dcB (3ABA (3GFE|
DAFA DAFA|defe dcBA|eAfA gfec|d2 f2 d2:|
X: 2
T: The Harvest Home
R: hornpipe
M: 4/4
L: 1/8
K: Dmaj
vcud|vD2 FA (DA)FA|vd(ef)c (dc)BA|v(e/f/g)fa (ga)fg|ve(dc)B (AG)FE|
vD2 FA (DA)FA|d(ef)c (dc)BA|(e/f/g)fa (ge)cA|d(gf)e d2 AF|
vD2 FA (DA)FA|d(ef)c (dc)BA|(e/f/g)fa (ga)fg|ve/uf/vedB (AG)FE|
vD2 FA (DA)FA|d(ef)c (dc)BA|ve/uf/vgfa (ga)fg|d(gf)e d2 cd|
v(eA)A/A/A (fA)A/A/(A|gA)fA eAA/A/A|v(e/f/g)fa g(gf)g|edcB A(GF)E|
vD2 FA (DA)FA|d(ef)c (dc)BA|(e/f/g)fa (ge)cA|d(gf)e d2 cd|
v(eA)A/A/A (fA)A/A/(A|gA)fA eAA/A/A|v(e/f/g)fa g(af)g|e/f/ed/c/B A/G/AF/G/E|
vD2 FA (DA)FA|d(ef)c (dc)BA|(e/f/g)fa (ge)cA|d(gf)e d2|
X: 3
T: The Harvest Home
R: hornpipe
M: 4/4
L: 1/8
K: Dmaj
"A"AF|:"D"DAFA DAFA|"D"defe dcBA|"A"eAfA gAfA|"Em"(3efe (3dcB "A7"(3ABA (3GFE|
"D"DAFA DAFA|"D"defe dcBA|"A7"eAfA gfec|1 "D"d2 f2 d2 "A"AF:|2 "D"d2 f2 d2 cd||
|:"A"eAA/G/A "D"fAA/G/A|"A7"gAfA "D"eAA/G/A|"A"eAfA gAfA|"Em"(3efe (3dcB "A7"(3ABA (3GFE|
"D"DAFA DAFA|"D"defe dcBA|"A7"eAfA gfec|1 "D"d2 f2 d2 cd:|2 "D"d2 f2 d4||
X: 4
T: The Harvest Home
R: hornpipe
M: 4/4
L: 1/8
K: Dmaj
A2|:"1"D2 (3FGA DAFA|BGec dcBA|"2"eAfA gefd|(3efe (3dcB (3ABA (3GFE|
D2 (3FGA EAFA|BGec dcBA|1 eAfA gece|dfec d2A2:|2 eAfA gece|dfec d2cd||
"3"eA (3cBA fA (3cBA|g (3cBA f (3cBA|eAfA gefd|(3efe (3dcB (3ABA (3GFE|
D2 (3FGA DAFA|BGec dcBA|1 eAfA gece|dfec d2cd|2 eAfA gece|dfec d2||
"Variations" "1"~D2 (3FGA DAFA|"2" ~e3f gfgf|edcB (3ABA (3GFE|"3" e AAA fAAA|gAAA fAAA|
X: 5
T: The Harvest Home
R: hornpipe
M: 4/4
L: 1/8
K: Dmaj
|:A>G|F>AD>A F>AD>A|d>ef>e d>cB>A|e>Af>A g>Af>A|e>dc>B (3ABA (3GFE|
D>AF>A D>AF>A|d>ef>e d>cB>A|e>Af>A g>ec>e|d2 f2 d2:|
|:c>d|e>AA>A f>AA>A|g>Af>A e>AA>A|e>Af>A g>Af>A|e>dc>B (3ABA (3GFE|
D>AF>A D>AF>A|d>ef>e d>cB>A|e>Af>A g>ec>e|d2 f2 d2:|
X: 6
T: The Harvest Home
R: hornpipe
M: 4/4
L: 1/8
K: Gmaj
|:BdGd BdGd|gbab gfed|eAab c'abg|(3aba (3gfe dcBA|
BdGd BdGd|gbaf gfed|(3efg ab c'afa|g2 gf [1 gedc:|2 gd (3efg||
ad (3ddd ed (3ddd|c' (3ddd ed (3ddd|eAab c'abg|(3aba (3gfe dcBA|
BdGd BdGd|gbaf gfed|(3efg ab c'afa|g2 gf [1 gd (3efg|2 gedc:|
X: 7
T: The Harvest Home
R: hornpipe
M: 4/4
L: 1/8
K: Dmaj
|:AF|DAFA DAFA|defe dcBA|eAfA gAfA|edcB AGFE|
DAFA DAFA|defe dcBA|eAfA gece|d2 f2 d2:|
|:cd|eA (3AAA fA (3AAA|gAfA eA (3AAA|eAfA gAfA|(3efe (3dcB (3ABA (3GFE|
DAFA DAFA|defe dcBA|eAfA gece|d2 f2 d2:|
X: 8
T: The Harvest Home
R: hornpipe
M: 4/4
L: 1/8
K: Dmaj
|:AF|(3DAA (3FAA (3DAA (3FAA|defe dcBA|(3eAA (3fAA (3gAA (3fAA|(3efe (3dcB (3ABA (3GFE|
(3DAA (3FAA (3DAA (3FAA|defe dcBA|(3eAA (3fAA gfec|d2 f2 d2:|
|:cd|eAAA fAAA|GAfA eAAA|(3eAA (3fAA (3gAA (3fAA|(3efe (3dcB (3ABA (3GFE|
(3DAA (3FAA (3DAA (3FAA|defe dcBA|(3eAA (3fAA gfec|d2 f2 d2:|
X: 9
T: The Harvest Home
R: hornpipe
M: 4/4
L: 1/8
K: Dmaj
AF|:DAFA DAFA|defe dcBA|eAfA gAfA|edcB AGFE|
DAFA DAFA|defe dcBA|eAfA gece|1 d2 f2 d2 AF:|2 d2 f2 d2 cd||
|:eA A2 fA A2|gA A2 fA A2|eAfA gAfA|(3efe (3dcB (3ABA (3GFE|
DAFA DAFA|defe dcBA|eAfA gece|1 d2 f2 d2 cd:|2 d2 f2 d4||

My Lagan Love polka

X: 1
T: My Lagan Love
R: polka
M: 2/4
L: 1/8
K: Cmaj
(3G/A/B/|c2 (GF/E/)|C2 (B,>C)|(E2 FE)|(C3 C)|(C4|C3)||
G|A2 (3_BAB|c2 (GF/E/)|C2 (B,>C)|(E2 FE)|(C3 C)|C3||
(C/C/)|(EF) (A>G)|(3GFE (FA/B/)|c2 (F (3A/G/A/ )|B2 c2|
_e (c2 B)|c2 (GF/E/)|C2 (B,z/C/)|(E2 FE)|(C3 C)|C3||
X: 2
T: My Lagan Love
R: polka
M: 2/4
L: 1/8
K: Cmaj
3de/f/|g3d cB/G/|F3G Bc/d/|c3B (G>G|G3)d/e/ fe/f/|
g3d cB/G/|F3G Bc/d/|c3B G>G|G3G Bc|
e3d dc/B/|c4 ef|g3c ed/e/|^fg g_b g=f|
g3d (3cBG|F3G Bc/d/|c3B G>G|G4||
X: 3
T: My Lagan Love
R: polka
M: 2/4
L: 1/8
K: Amix
((3ef/g/|a3e (3dcA|G3 ) (A (3cde|d3/2c/ AA|
A3) (e/f/ (3gfg|aa2 e (3dcA|G3) (A (3cde|d3/2c/ AA|
A3) (A cd|f3/2e/ ef//e//d/c/|d3) (dfg|a3 d (3fef|^g3 a a4)|
(=c'4 a3 g|a3 e (3dcA|G3) (A (3cde|d3/2c/ AA|A4):|

The Pretty Girl Milking Her Cow waltz

X: 1
T: The Pretty Girl Milking Her Cow
R: waltz
M: 3/4
L: 1/8
K: Ador
L:1/4
A/B/|cee/d/|Bdd/B/|A/B/G2-|G2A/B/|cee/d/|Bdd/B/|A3-|A>B A/B/|
cee/d/|Bgd/B/|A/B/G2-|G>f g/f/|e/d/ c/B/ A/G/|EA>B|A3-|A2:|A/B/|
cc/d/ e/f/|gg/e/ d/B/|A/B/G2-|G2A/B/|cc/d/ e/f/|geg|a3-|a>a b/a/|
gg/e/d/c/|d/g/ G/B/ d/B/|A/4B/4A/G2-|G>f g/f/|e/d/ c/B/ A/G/|EA>B|A3-|A2A/B/||
cc/d/ e/f/|gg/e/ d/B/|A/B/G2-|G2A/B/|cc/d/ e/f/|gc'>b|a3-|a>a b/a/|
gg/e/d/c/|d/g/ G/B/ d/B/|A/4B/4A/^G2-|^G>f g/f/|e/d/ c/B/ A/G/|EA>B|A3|A2||
X: 2
T: The Pretty Girl Milking Her Cow
R: waltz
M: 3/4
L: 1/8
K: Ador
AB|cz e3d|Bzd3B|AGHE4|z2z2AB|cze3d|Bzd3B|HA6|zzAB|
cze3d|Bzd3B|AGHE4|z2z2AB|cBAGED|E2A2((3^GAB)|HA6|zz:|
|:AB|c2d2e2|eza2((3^gab)|azA4|z2z2AB|c2d2e2|eza2((3^gab)|Ha6|z2z2ab|
c'2b2a2|(ge3)d2|cA3dc|AGE4|z2z2AB|cBAGED|E2A2((3^GAB)|HA6|z2z2:|
X: 3
T: The Pretty Girl Milking Her Cow
R: waltz
M: 3/4
L: 1/8
K: Cmaj
"_vb"(AB)|(c2e2c2)|(B2d2B2)|(A2G4-|G4)(AB)|(c2e2c2)|(B2d2B2)|A6-|A4(AB)|
(c2e2c2)|.B2"^>"g2.B2|.A2G4-|G4(e3/2d/)|(c2B2A2)|(E2A2B2)|A6-|A4||
(AB)|(c2d2e2)|(e2^f2^g2)|a2A4-|A4(AB)|c2d2(e{fe}d)|e2(a2{c'}b2)|a6-|a2(b3a)|
(g2e2d2)|.B2"^>"g2.B2|.A2G4-|G4(ed)|(c2B2A2)|(E2A2B2)|A6-|A4||
"_vb"(AB)|(c2e2c2)|(B2d2B2)|(A2G4-|G4)(AB)|(c2e2c2)|(B2d2B2)|A6-|A4(AB)|
c2e2c2|B2g2B2|A2G4-|G4(e3/2d/)|(c2B2A2)|(E2^F2^G2)|A6-|A4||
G2|c3(de^f)|(g2e2c2)|(B2G4-|G4)G2|c3(de^f)|{a}g2 e2^g2|a6-|a4(ba)|
g3(fed)|B2g2B2|A2G4-|G4(ed)|c3(BAG)|(E2^F2^G2)|A6-|A4||
X: 4
T: The Pretty Girl Milking Her Cow
R: waltz
M: 3/4
L: 1/8
K: Ador
c2 e2 ed|B2 d2 dB|AB G4-|G4 AB|c2 e2 ed|B2 d2 dB|A6-|A3 B AB|
c2 e2 ed|B2 g2 dB|AB G4-|G3 f gf|ed cB AG|E2 A3 B|A6-|A4:|
c2 cd ef|g2 ge dB|AB G4-|G4 AB|c2 cd ef|g2 e2 g2|a6-|a3 a ba|
g2 ge dc|dg GB dB|A/B/A G4-|G3 f gf|ed cB AG|E2 A3 B|A6-|A4 AB||
c2 cd ef|g2 ge dB|AB G4-|G4 AB|c2 cd ef|g2 c'3 b|a6-|a3 a ba|
g2 ge dc|dg GB dB|A/B/A ^G4-|^G3 f gf|ed cB AG|E3 A3 B|A6|A4||
X: 5
T: The Pretty Girl Milking Her Cow
R: waltz
M: 3/4
L: 1/8
K: Ddor
DE|F2 A3 F|E2 G3 E|D2 (C4|C6) DE|
F2 A3 F|E2 G3 E|(D6|D4) DE|
F2 A3 F|E2 c3 E|D2 (C4|C6)|
A3 G FE|D A,3 DE|(D6|D4)||
DE|F3 G AB|c G3 FE|C4 DE|F3 GAB|
c2 A2 (3ABc|d6|e3 d c2|G2 FE c2|
ED C4|A2 GFED|A,2 D2 E2|D4|
X: 6
T: The Pretty Girl Milking Her Cow
R: waltz
M: 3/4
L: 1/8
K: Ador
A2|c2 e2 c2|B2 d2 BA|G2 HA2 AB|c2 d2 e2|e2 f2 g2|Ha4 gf|
g2 f2 e2|d2 e2 BA|G2 HA2 ed|c2 B2 A2|E2 A2 G2|HA4|
X: 7
T: The Pretty Girl Milking Her Cow
R: waltz
M: 3/4
L: 1/8
K: Ador
(AB)|c3e c2|Bd3 B2|A4(G2|G4) AB|c3e c2|Bd3 B2|A6-|A4(AB)|
ce3 c2|B2 g>c {d}cB|G2G4-|G4 ee/d/|c2 B{B}B AA/G/|E2 A3B|A6-|A4 AB||
c2 B{B}B A>B|d2 B<A B>G|G2 G2 AB|c2 B{B}B A>B|d2 d2 B2|A2 A2 AB|
c{d}c c<B B<A|B2 B2 g2|g2 c{d}c/B/ B<G|G4 e2|e2 ed/B/ c2|
c2 B{B}B AA/G/|E2 A3B|A6|A2 AB c2|d2 ef g2|
g4 c{d}c|B{B}B G4|GG/F/ GA Bc|c2 cB cd|ea a4|{aba}ag a4|
b2 c'2 b2|a4 ag|e2 =f4|ee/d/ BA Bd|d2 BA A2|G4 AB|
c2 B{B}B AA/G/|E2 A3B|A6|AB c3e|e2 c3B|Bd d2 BA|AG G4|
AB c3e|cA Bd d2|B2 B{B}B A2|A2 AB c2|ce e2 cB|Bg g2 cc/B/|
B<G G4|e2 ed cB|c2 B{B}B AA/G/|E2 A3B|A6|A4 AB|
c3B cd|ef g4|cc/B/ B<G G2|GG/F/ GA Bc|c2 cB cd|ea a4|{aba}ag a4|
b2 c'2 b2|a4 ag|e2 =f4|ee/d/ BA Bg|g2 c2 ^A=A|A2 G4|
AB c2 B{B}B|AA/G/ e2 A2|AB A4|A6||
X: 8
T: The Pretty Girl Milking Her Cow
R: waltz
M: 3/4
L: 1/8
K: Ador
(A>B)|ce4 c|Bd4 B|A2 (G4|HG4) A>B|c2e3 c|Bd4 B|A6-|HA4 (A>B)|
ce4 c|B Hd4 B|A2 {BA}(G4|HG4) {d}e>d|c>B A>E (A2|A4){BcB}A2-|A6-|HA4(A>B)|
c3d e<f|g3 c2A|BG3-G2-|HG4 A>B|c3d e<f|g>{a}g e>g a2-|a4 {g}ba|
{f}g3{a}g/e/d2-|d4e<c|A<B g2 B<A|{BA}HG4 {d}e>d|c>B A>E (A2|A4){BcB}A2-|A6-|HA4(A>B)|
ce4 c|Bd4 B|A2 {BA}(G4|HG4) A>B|c2e3 c|Bd4 {ed}B|A6-|HA4 (A>B)|
c4 {dc}B>A|B Hd4 {ed}B|A2 {BA}(G4|HG4) {d}e>d|c>B A>E (A2|A4){BcB}A2-|A6-|HA4(A>B)|
c3d e<f|g3 {cd}c2A|BG3-G2-|HG4 A>B|c3d e<f|g>{a}g e>g a2-|a4 {a}ba|
{f}g3{a}g/e/d2-|d4e<{B}c|A<B g2 {Bc}B<A|HG4 {d}e>d|c>B A>E (A2|A4){BcB}A2-|A6-|HA6|
X: 9
T: The Pretty Girl Milking Her Cow
R: waltz
M: 3/4
L: 1/8
K: Emin
EF|G2B3G|F2A3F|E3F ED-|D4EF|G2B3G|F2A3F|E6-|E4EF|
G2B3G|F2A3F|E3F ED-|D6BA|G3FE2|D3EF2|E6-|E4:|
|:D2|G3AB2|d3BG2|F2D4-|D4D2|G3AB2|d2B2d2|e6-|e4ef|
g3fe2|d3BG2|F2D4-|D4BA|G3FE2|D3EF2|E6-|E4:|

The Princess Royal strathspey

X: 1
T: The Princess Royal
R: strathspey
M: 4/4
L: 1/8
K: Emin
|:BA G2 F2 E2|BA G2 F2 E2|B2 c2 B2 A2|dc Bc BA G2|
B2 AB AG FA|FE DD EF G2|BA G2 FE GF|ED E2 E2 E2:|
|:B2 e2 cd e2|f2 g2 G2 G2|g2 gf ed cB|AG FG FE D2|
EF G2 FG A2|GA B2 B2 e2|c2 d2 G2 c2|dc B2 G2 A2|
BA AG FE DD|EF G2 BA G2|FE GF ED E2|E4 E4:|
X: 2
T: The Princess Royal
R: strathspey
M: 4/4
L: 1/8
K: Dmin
A/G/|FE DA/G/|FE DA|BA Gc/B/|A/B/A/G/ FA|
G/A/G/F/ E/F/E/D/|CB, A,A/G/|FE/D/ F/E/D/^C/|D2 D||
A|d3/2^c de|fF Ff|f/e/d/c/ B/A/G/F/|E/F/G/E/ CD/E/|
FE/F/ GF/G/|AA d2|c2 Bc/B/|A2 GA/G/|
G/F/F/E/ D/F/E/D/|C/D/C/B,/ A,A/G/|FE/D/ F/E/D/^C/|D2 D||