back menu
Log in or Sign up

Music In The Glen reel

Also known as Ceol Sa Ghleann, Down On The Hollow Low Land, The Music In The Glen.

There are 108 recordings of this tune.

This tune has been recorded together with

Music In The Glen appears in 4 other tune collections.

Music In The Glen has been added to 69 tune sets.

Music In The Glen has been added to 590 tunebooks.

Download ABC

Twelve settings

1
X: 1
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:G2BG EGDC|B,DGB AGAB|c2ec BcdB|cABG AGED|
GABG EGDC|B,DGB AGAB|cdef g2ge|dBAB G2|D2:|
|:B/A/G dG eGdG|BGdB cAAA|B/A/GBd edef|gdBG AGEG|
BGBd edef|g2fg afdf|g2fg egdB cABG AGEG:|
2
X: 2
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:G2BG EGDC|B,DGB AGAB|C2EC B2DB|AGAB AGEF|
G2BG EGDC|B,DGB AGAB|cdef gfge|dcBA G4:|
|:B2dB eBdB|B2dB ABGA|B2dB eBde|gdBG AGEG|
B2dB eBdB|g2fg agef|g2fg egdB|cABG AGEF:|
3
X: 3
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:G2BG EGDc|BDGB AGAB|cdec BBdB|BAAG AGEF|
GABG EGDc|BDGB AGAB|cdef g2ge|dcBA G2D2:|
|:BG dG egdA|AGdB cAFA|BG dG eg de|gdcA BGED|
AG dG egde|ggfg a~f3|g2fg (3efg dB|cABG AGEF:|
4
X: 4
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Gmaj
G2BG EGDc|BDGB AGAB|cdec BBdB|BAAG AGEF|
GABG EGDc|BDGB AGAB|cdef g2ge|dcBA G2 D2|
G2BG EGDc|BDGB AGAB|cdec ABBB|BABG AGEF|
GABG EGDc|BDGB AGAB|cdef g2ge|dcBA G2 D2|
|:BGdG egdA|AGdB cAFA|BGdG eg de|gdBG AGEG|
AGdG egde|ggfg a~f3|g2fg (3efg dB|BABG AGEG:|
5
X: 5
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Gmaj
G2 BG EFGC|B,DGB A3B|c2 ec B2 dB|BABG AGEF|
G2 BG EFGC|B,DGB A3B|cdef gbge|dcBA G3 D|
G2 BG EFGC|B,DGB A3B|cece BdBd|A3 B AGEF|
G2 BG EFGC|B,DGB A3B|cdef gbge|dcBA G4||
|:BGdG e2dc|BGdG BA F2|BGdG eg (3def|gdBG AGE2|
BGdG e2df|g2 fg afdf|g2 fgeg dB|1 cABG AG EF:|2 c2 (3BcB AGEF||
6
X: 6
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Amaj
|:A2cA FAED|CEAc BABc|d2fd cdec|dBcA BAFE|
ABcA FAED|CEAc BABc|defg a2af|ecBc A2E2:|
|:c/B/A eA fAeA|cAeA dBBB|c/B/A ce fefg|aecA BAFA|
cAce fefg|a2 ga bgeg|a2 ga faec|dBcA BAEA:|
7
X: 7
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:G2BG EGDc|BDGB AGAB|cdec BcdB|A3G AGEF|
GABG EGDc|BDGB AGEG|(3Bcd ef g3e|dBAc BG G2:|
|:BGdG egdc|BGdG BA3|BGdG egdc|(3Bcd Ac BG G2|
BGdG egdc|BGdG BA3|g2 fg (3efg dc|(3Bcd Ac BG G2:|
# Added by JACKB .
8
X: 8
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Fmaj
|:F2AF DFCB,|A,CFA GFGA|B2dB ABcA|BGAF GFDC|
FGAF DFCB,|A,CFA GFGA|Bcde f2fd|cAGA F2C2:|
|:A2 cF dFcF|AFcA BG~G2|AF Ac ~d3e|fcAF GFDF|
AFAc dcde|f2ef gece|f2ef dfcA BGAF GFDF:|
9
X: 9
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:"G"G2BG EGDC'|B',DGB AGAB|"C"cdec "C(B)"B2 (3dcB|"Am"BAAG "D"AGEF|
"G"GABG EGDC'|B',DGB AGAB|"C"cdef ~g3e|1 "D"dcBA "G"G2EF:|2 "D"dcBA "G"~G3A||
|:"G"BGdG eGdG|(3BAG dB "D"cAFA|"G"BGdG eGdf|gdBG "D"AGEG|
"G"(3BAG dG eGdf|g2 fg "D"afdf|"Em"g2fg egdB|"C"cABG "D"AGEG:|
# Added by cheip .
10
X: 10
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:G2BG E/F/G dc|BDGB AGAB|c2ec BdGB|cABG AGE2|
GABG E/F/G dc|BDGB AGAB|cdef gfge|1 dcBA G2(3DEF:|2 dcBA G2zA||
BG~G2 EGdG|BGDG cAFA|BGdG eG(3def|gdBG AGEG|
BGdG eGd2|gfgb afdf|gefd eBdB|cABG AGE2|
BG~G2 eGdG|BGdG cAFA|BGdG eG(3def|gdBG AGE2|
BGdG eGdf|gfgb afdf|g2fg egdB|cABG AGEF||
11
X: 11
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:G2BG (3EFG Dc|BDGB AGAB|c2ec BBdB|cABG AGEF|
G2BG (3EFG Dc|BDGB AGAB|cdef ~g3e|1 dcBA G3D:|2 dcBA G3A||
|:BG dG eGdG|BGdB cAFA|BG dG ~e3f|gdBG AGEG|
BG dG ~e3f|g2fg afdf|g2fg (3efg dB|cABG AGEF:|
12
X: 12
T: Music In The Glen
R: reel
M: 4/4
L: 1/8
K: Gmaj
|:G2BG EGDC|B,DGB AGAB|c2ec B2dB|cABG AGEF|
G2BG EGDC|B,DGB AGAB|cdef g2fe|1 dcBA G2DE:|2 dcBA G2GA||
|:BGdG eGdG|BGdB cAFA|BGdG edef|gedB AGEG|
BGBd edef|g2fg afdf|gefd egdB|1 cABG AGEG:|2 cABG AGEF||

Twenty-one comments

Change the key

Transposing up to A is fun on fiddle…

Posted by .

Already here - “Music In The Glen”

Looks to me like “The Music In The Glen”, which has been here since 2001. Sorry.

Posted by .

Yukky transcription too - sorry to be blunt.

Looks to me like this version attracted
two sorry commentators.

Posted by .

Naw Laitch, could have checked that it was there (so get rid of this) and the transcription isn’t great.

heh

Posted by .

Originally in A

The tune was originally given to Francis O’Neill in A by tipperary fiddle player Edward Cronin.

Excellent rendition (casual session) by Peter Horan and Fred Finn on youtube.

Bothy Band

X: 1
T: Music In The Glen
M: 4/4
L: 1/8
R: reel
K: Gmaj
|:G2BG EGDc|BDGB AGAB|cdec BBdB|BAAG AGEF|
GABG EGDc|BDGB AGAB|cdef g2ge|dcBA G2|D2:|
|BG dG egdA|AGdB cAFA|BG dG eg de|gdcA BGED|
|AG dG egde|ggfg a~f3|g2fg (3efg dB| cABG AGEF|

V 2

X: 1
T: Music In The Glen
M: 4/4
L: 1/8
R: reel
K: Gmaj
|:G2BG EGDc|BDGB AGAB|1 cdec BBdB|BAAG AGEF|2 cdec ABBB|BABG AGEF|
GABG EGDc|BDGB AGAB|cdef g2ge|dcBA G2|D2:|
|BG dG egdA|AGdB cAFA|BG dG eg de|gdBG AGEG|
|AG dG egde|ggfg a~f3|g2fg (3efg dB| BABG AGEG|

Music in the Glen

I sometimes here this version in sessions. I think it is same tune.

X:1
T: Music in the Glen
K:G
G2 BG DGDC|B,DGB cBAG| c2 ec B2 dB|AGAB cBAF|
G2 BG DGDC|B,DGB cBAG| cdef gedc |BGAF G3 A||
B2 dG eGdG|B2dB AGEG| B2 dG e2ef| gedB cAFA|
B2 dG eGdG|B2 dB Bdef|g2 fg e2 dB|c2 Bc AGEG||

Horan / Finn version

I based my transcription from the playing of Horan (mainly) and Finn on the above mentionned video, as far as my ears don’t fool me, for example on “ghost notes” (are they ?) in the cece BdBd pattern of the first part second time.
Is the second part in GMaj, or Emin as it can resolve on E ?

Re: Music In The Glen

So many play it in G, but the A version as in O’Neil’s fits under the fingers much better for fiddle or mandolin; and sounds much brighter.

Music In The Glen, X:12

I find the pedal bowing bit at the start of the second part quite challenging!

This setting is from the playing of Clare Friel who taught it to students at Belfast Trad Fest winter weekend recently.